Início / dba / Perguntas / 45526
Accepted
biziclop
Asked: 2013-07-02 07:41:18 +0800 CST

Como determinar a pegada de armazenamento Oracle LOB?

  • 772

Com SECUREFILEo armazenamento, posso especificar se quero compactação (e o nível dela) e desduplicação, e tudo é uma troca entre tempo e espaço.

O tempo é bastante fácil de perfilar, mas qual é a maneira mais fácil de obter uma medição razoavelmente precisa de quanto espaço uma coluna LOB específica ocupa?

oracle-11g-r2 storage

1 respostas

  1. Best Answer

    Você pode obter o tamanho em bytes da coluna BLOB via DBMS_LOB.GETLENGTH(...).

    Para obter um tamanho total em bytes de coluna para toda a tabela SUM, faça assim:

    SELECT SUM(DBMS_LOB.GETLENGTH(my_blob_column)) as total_bytes
FROM my_table

    Se você marcou a coluna BLOB como desduplicada, pode executar algo como o seguinte para obter estatísticas sobre o tamanho real em bytes usados. Compare o used_bytesvalor antes/depois de ativar as configurações que podem alterar o tamanho da coluna BLOB (por exemplo, desduplicação, compactação etc.).

    declare  
    p_schema_name           varchar(256) DEFAULT 'THE_SCHEMA_NAME';
    p_table_name            varchar(256) DEFAULT 'THE_TABLE_NAME';
    --
    l_segment_name          varchar2(30);
    l_segment_size_blocks   number; 
    l_segment_size_bytes    number; 
    l_used_blocks           number;  
    l_used_bytes            number;  
    l_expired_blocks        number;  
    l_expired_bytes         number;  
    l_unexpired_blocks      number;  
    l_unexpired_bytes       number;  

begin
    FOR rec IN (select segment_name 
                from dba_lobs 
                where owner = p_schema_name
                  and table_name = p_table_name
                order by 1)
    LOOP
        dbms_output.put_line('Segment Name=' || rec.segment_name);

        dbms_space.space_usage( 
            segment_owner           => p_schema_name,  
            segment_name            => rec.segment_name, 
            segment_type            => 'LOB', 
            partition_name          => NULL, 
            segment_size_blocks     => l_segment_size_blocks, 
            segment_size_bytes      => l_segment_size_bytes, 
            used_blocks             => l_used_blocks, 
            used_bytes              => l_used_bytes, 
            expired_blocks          => l_expired_blocks, 
            expired_bytes           => l_expired_bytes, 
            unexpired_blocks        => l_unexpired_blocks, 
            unexpired_bytes         => l_unexpired_bytes 
        );   


        dbms_output.put_line('  segment_size_blocks       => '||  l_segment_size_blocks);
        dbms_output.put_line('  segment_size_bytes        => '||  l_segment_size_bytes);
        dbms_output.put_line('  used_blocks               => '||  l_used_blocks);
        dbms_output.put_line('  used_bytes                => '||  l_used_bytes);
        dbms_output.put_line('  expired_blocks            => '||  l_expired_blocks);
        dbms_output.put_line('  expired_bytes             => '||  l_expired_bytes);
        dbms_output.put_line('  unexpired_blocks          => '||  l_unexpired_blocks);
        dbms_output.put_line('  unexpired_bytes           => '||  l_unexpired_bytes);
    END LOOP;
end;
/

    Este código é uma versão ligeiramente modificada do código na postagem da Oracle explicando como funciona a desduplicação. O original está disponível aqui: http://www.oracle.com/technetwork/articles/sql/11g-securefiles-084075.html .

    • 3

relate perguntas