Restaurar o backup mais recente no banco de dados

Se você não tiver acesso ao servidor original e tudo o que tiver for o arquivo de backup, precisará restaurar os cabeçalhos do arquivo de backup primeiro para ver o que há dentro dele.

Você pode fazer isso por:

create table #headers 
(
BackupName              nvarchar(128),
BackupDescription       nvarchar(255),
BackupType              smallint,
ExpirationDate          datetime,
Compressed              bit,
Position                smallint,
DeviceType              tinyint,
UserName                nvarchar(128),
ServerName              nvarchar(128),
DatabaseName            nvarchar(128),
DatabaseVersion         int,
DatabaseCreationDate    datetime,
BackupSize              numeric(20,0),
FirstLSN                numeric(25,0),
LastLSN                 numeric(25,0),
CheckpointLSN           numeric(25,0),
DatabaseBackupLSN       numeric(25,0),
BackupStartDate         datetime,
BackupFinishDate        datetime,
SortOrder               smallint,
[CodePage]              smallint,
UnicodeLocaleId         int,
UnicodeComparisonStyle  int,
CompatibilityLevel      tinyint,
SoftwareVendorId        int,
SoftwareVersionMajor    int,
SoftwareVersionMinor    int,
SoftwareVersionBuild    int,
MachineName             nvarchar(128),
Flags                   int,
BindingID               uniqueidentifier,
RecoveryForkID          uniqueidentifier,
Collation               nvarchar(128),
FamilyGUID              uniqueidentifier,
HasBulkLoggedData       bit,
IsSnapshot              bit,
IsReadOnly              bit,
IsSingleUser            bit,
HasBackupChecksums      bit,
IsDamaged               bit,
BeginsLogChain          bit,
HasIncompleteMetaData   bit,
IsForceOffline          bit,
IsCopyOnly              bit,
FirstRecoveryForkID     uniqueidentifier,
ForkPointLSN            numeric(25,0),
RecoveryModel           nvarchar(60),
DifferentialBaseLSN     numeric(25,0),
DifferentialBaseGUID    uniqueidentifier,
BackupTypeDescription   nvarchar(60),
BackupSetGUID           uniqueidentifier,
CompressedBackupSize    bigint,
Containment             tinyint
);
go

insert into #headers exec('restore headeronly from disk=''c:\DEV\UnitTest.bak''');
go 

Agora você tem uma tabela temporária ( #headers) que contém detalhes de todos os backups contidos nesse arquivo de dispositivo.

Para encontrar o backup completo do banco de dados mais recente, filtramos apenas os backups completos do banco de dados ( backupType=1) e, em seguida, procuramos o backup mais recente no dispositivo, que será aquele com o maior LSN. Isso nos dá o valor da posição, que é usado no RESTOREcomando para especificar ao SQL Server qual backup queremos restaurar:

declare @filepos int;
select top 1 @filepos=Position from #headers where BackupType=1 order by lastlsn desc;
restore database unittest from Disk=N'c:\DEV\UnitTest.bak' with file=@filepos, recovery, replace;

Como você disse ainda terá acesso ao servidor original, podemos então consultar as tabelas no msdb que o SQL Server usa para armazenar essas informações.

As consultas a seguir pressupõem que você as esteja executando em uma sessão SQL no servidor original. Se você não tem permissão para fazer isso, precisará procurar usar um servidor vinculado e nomenclatura de 4 partes.

Existem 2 maneiras de especificar o conjunto de backups que deseja examinar. Uma é através do caminho para o arquivo de backup, a outra é referenciando o nome no dispositivo de backup. Incluí ambos nesta consulta, com algumas notas sobre quais linhas comentar, dependendo de como você está fazendo isso.

Isso produzirá uma RESTOREinstrução que você pode executar em uma sessão separada do SSMS. Também incluí um exemplo na parte inferior de como você pode automatizar isso, embora queira fazer alguns testes antes para ter certeza de que está fazendo o que deseja.

declare @filepos int, @dbname varchar(50), @devname varchar(50)

/*
dbname is the name of the database you want to restore. Need this, as it's possible for backups of more than one database to be present in the same backup file or device

devname is either the name of the backup device, or the path to the .bak file
*/

select @dbname='Unittest', @devname='c:\DEV\unittest.bak'

select @filepos=max(c.position) 
from 
msdb.dbo.backupmediafamily a 
inner join msdb.dbo.backupmediaset b on a.media_set_id=b.media_set_id
inner join msdb.dbo.backupset c on b.media_set_id=c.media_set_id
where 
a.physical_device_name=@devname  --use this line if you know the path to the backup
--a.logical_device_name=@devname --this line if you only know a device name.
and c.type='D' and c.database_name=@dbname

--This will build the restore statement if you know the device name
select 'restore database ['+@dbname+'] from '+@devname+' with file='+cast(@filepos as varchar(4))+', recovery, replace' 

--This will build the restore statement if you know the backup file path
select 'restore database ['+@dbname+'] from disk=N'''+@devname+''' with file='+cast(@filepos as varchar(4))+', recovery, replace' 

/*
This section only if feeling brave and confident, and you've checked the output previously, as it will execute whatever the generated restore command is, so this could cause a major problem if not checked first, or even overwrite production if run on the wrong box.
*/

declare @restore_cmd varchar(250)
select @restore = 'restore database ['+@dbname+'] from disk=N'''+@devname+''' with file='+cast(@filepos as varchar(4))+', recovery, replace' 
exec(@restore)

Isso deve lhe dar um começo:

SELECT 
  s.name, 
  s.backup_start_date, 
  s.backup_finish_date, 
  mf.physical_device_name,
  s.first_lsn, s.last_lsn, s.database_backup_lsn
FROM 
  msdb.dbo.backupset AS s
INNER JOIN 
  msdb.dbo.backupmediaset AS ms
  ON s.media_set_id = ms.media_set_id
INNER JOIN 
  msdb.dbo.backupmediafamily AS mf
  ON ms.media_set_id = mf.media_set_id
WHERE 
  s.database_name = N'UnitTest' 
ORDER BY 
  s.backup_finish_date DESC;