Início / dba / Perguntas / 340081
Accepted
SomeBody
Asked: 2024-06-07 21:43:40 +0800 CST

A execução do gatilho pós-inserção é concluída quando a próxima entrada é inserida?

  • 772

Tenho um banco de dados SQL Server com uma tabela com um gatilho que é executado após a inserção. Se eu inserir duas entradas diretamente, uma após a outra, é importante que a segunda entrada seja inserida somente após o término da execução do gatilho. Posso confiar nisso? Ou posso ter uma condição de corrida problemática em algum momento?

O código do gatilho fica assim:

ALTER TRIGGER [dbo].[TR_MachineState_Desable_OldData_ON_Insert]
   ON [dbo].[machine_state]
   AFTER INSERT
AS 
BEGIN
      DECLARE @RowID INT;
      DECLARE @Name NVARCHAR(30);
      DECLARE @MachineState NVARCHAR(30);
      DECLARE @Devicescount INT;
      DECLARE @StartedOn DATETIME;
      DECLARE @CreateOn DATETIME;
      DECLARE @ToolName NVarchar(30);


    -- SET NOCOUNT ON added to prevent extra result sets from
    -- interfering with SELECT statements.
    SET NOCOUNT ON;

    -- Insert statements for trigger here
          SELECT
                   @RowID=[RowId]
                  ,@Name= [Name]
                  ,@MachineState=[MachineState]
                  ,@Devicescount=[Devicescount]
                  ,@StartedOn= [StartedOn]
                  ,@CreateOn =[ActionDate]
                  ,@ToolName=[ToolName]
        from inserted ;

    update [machine_state]
    set [IsActive]=0
    where  [Name] =@Name and  ToolName = @ToolName and  RowId <> @RowID

    update machine_state
    set IsActive =1
    where RowId=@RowID


END

Como você pode ver, o gatilho garante que apenas a última entrada com o mesmo nome de ferramenta e o mesmo nome seja IsActiveverdadeira.

sql-server

2 respostas

  1. Oh céus

    Você terá um problema muito maior se alguém inserir mais de uma única linha nessa tabela. Seu gatilho terá um tempo de coisas bastante não determinístico.

    Mas não, não há garantia de que seu gatilho terá concluído a execução quando outra linha chegar.

    Você pode tentar suas inserções em maior simultaneidade com uma ferramenta como SQL Query Stress .

    • 5
  2. Best Answer

    Embora não haja garantia sobre a execução de gatilhos de instruções diferentes, o bloqueio correto deve evitar o surgimento de quaisquer problemas.

    Conforme mencionado por outros, você precisa corrigir seu bug gigante onde você não está manipulando múltiplas (ou zero!) linhas corretamente.

    CREATE OR ALTER TRIGGER [dbo].[TR_MachineState_Desable_OldData_ON_Insert]
   ON [dbo].[machine_state]
   AFTER INSERT
AS

IF @@ROWCOUNT = 0
    RETURN;    -- early bailout

SET NOCOUNT ON;

IF EXISTS (SELECT 1
    FROM inserted i
    GROUP BY i.Name, i.ToolName
    HAVING COUNT(*) > 1
)
    THROW 50001, N'Multiple duplicate active rows', 1;

UPDATE others
SET IsActive = 0
FROM dbo.machine_state others
JOIN inserted i
  ON i.Name = others.Name
 AND i.ToolName = others.ToolName
 AND i.RowId <> others.RowID;

/*
-- DO NOT DO the below. Just change your insert to do it correctly the first time.

UPDATE ms
SET IsActive = 1
FROM inserted i
JOIN dbo.machine_state ms ON ms.RowId = i.RowID;
*/

    Você precisaria de um índice machine_state (Name, ToolName) INCLUDE (RowId, IsActive)para que o bloqueio funcionasse corretamente. Você também precisa daquela verificação extra que adicionei para garantir que alguém não tente adicionar Name, ToolNamelinhas duplicadas de uma só vez, caso contrário, os resultados seriam não determinísticos.

    Deixando tudo isso de lado, sugiro fortemente que você considere usar Temporal Tables , em vez de tentar lançar sua própria versão não muito boa do mesmo. As tabelas temporais lidam com linhas arquivadas e não ativas automaticamente, então você pode usar uma chave primária normal em Name, ToolName.

    • 1

relate perguntas