Quando ocorrem alterações de DML e DDL em uma tabela temporal, as alterações correlacionadas na tabela de histórico também são registradas no log de transações?

Sim, as alterações na tabela de histórico são registradas.

Se você pensar na finalidade do log de transações, é permitir a recuperação (por meio de backups e restaurações ou o processo de recuperação normal que ocorre na inicialização do banco de dados). Se as alterações na tabela de histórico não forem registradas, a restauração de um backup de um banco de dados com tabelas temporais provavelmente resultaria em inconsistências entre a tabela principal e a tabela de histórico.

Aqui está uma pequena demonstração. A configuração cria uma tabela temporal, insere uma linha, atualiza essa linha e limpa o log.

USE [master];
GO

DROP DATABASE IF EXISTS [315097];
GO

CREATE DATABASE [315097];
ALTER DATABASE [315097] SET RECOVERY SIMPLE 
GO

USE [315097];
GO

CREATE TABLE dbo.Employee
(
    EmployeeID int NOT NULL, 
    [Name] nvarchar(100) NOT NULL, 
    Position varchar(100) NOT NULL, 
    Department varchar(100) NOT NULL, 
    [Address] nvarchar(1024) NOT NULL, 
    AnnualSalary decimal (10,2) NOT NULL, 
    ValidFrom datetime2 GENERATED ALWAYS AS ROW START, 
    ValidTo datetime2 GENERATED ALWAYS AS ROW END,

    PERIOD FOR SYSTEM_TIME (ValidFrom, ValidTo),
    CONSTRAINT PK_Employee PRIMARY KEY (EmployeeID)
)
WITH 
(
    SYSTEM_VERSIONING = ON (HISTORY_TABLE = dbo.EmployeeHistory)
);
GO

/*
INSERT an initial row to avoid a lot of "noise" in this test related to inserting
the very first row into these tables
*/
INSERT INTO dbo.Employee
    (EmployeeID, [Name], Position, Department, [Address], AnnualSalary)
VALUES
    (1, N'Josh', 'Trusted User', 'I.T.', N'123 Main St', 3.50);

UPDATE dbo.Employee
SET AnnualSalary = 4.00;
GO

/*
Clear the log
*/
BACKUP DATABASE [315097] TO DISK = N'NUL';
GO
CHECKPOINT;
GO
/*
Query showing only checkpoints
*/
SELECT 
    l.[Current LSN],
    l.Operation,
    l.Context,
    l.AllocUnitName
FROM fn_dblog(NULL, NULL) l;

Agora, se eu atualizar uma linha na tabela e executar a mesma consulta no log:

UPDATE dbo.Employee
SET AnnualSalary = 3.50;
GO

Esses 6 novos registros de log são:

• 2 para o início/fim da transação implícita
• 2 para atualizar o bitmap de backup diferencial
• 1 para a atualização da tabela base
• 1 para a inserção "oculta" na tabela de histórico

Se eu alterar a CREATE TABLEinstrução para remover os itens relacionados ao controle de versão do sistema e executar novamente a demonstração, o estado final do log ficará assim:

Isso significa que habilitar tabelas temporais efetivamente dobrará a quantidade de dados que passam pelo log de transações

Não será exatamente o dobro (inserções na tabela principal não fazem alterações na tabela de histórico), mas sim, haverá um aumento na taxa de transferência do log com certeza.