Início / dba / Perguntas / 25531
Accepted
Anthony
Asked: 2012-10-06 02:42:57 +0800 CST

Como posso obter o tamanho real dos dados por linha em uma tabela do SQL Server?

  • 772

Eu encontrei este script sql-server-2005-reaching-table-row-size-limit que parece retornar o tamanho da linha por comprimentos de tipo de dados definidos. Eu preciso de um script que me dê todas as linhas em uma tabela que seu tamanho máximo de dados está acima do recomendado 8024 (o que o MS recomenda)

sql-server

5 respostas

  1. Best Answer

    Tente este script:

    declare @table nvarchar(128)
declare @idcol nvarchar(128)
declare @sql nvarchar(max)

--initialize those two values
set @table = 'YourTable'
set @idcol = 'some id to recognize the row'

set @sql = 'select ' + @idcol +' , (0'

select @sql = @sql + ' + isnull(datalength(' + name + '), 1)' 
        from  sys.columns 
        where object_id = object_id(@table)
        and   is_computed = 0
set @sql = @sql + ') as rowsize from ' + @table + ' order by rowsize desc'

PRINT @sql

exec (@sql)

    As linhas serão ordenadas por tamanho, para que você possa verificar de cima para baixo. A rowsizecoluna está em bytes. Veja mais informações: DATALENGTH()

    • 60

  2. Eu gostei do Jaime acima . Eu adicionei alguns colchetes para lidar com nomes de colunas estranhos.

        declare @table nvarchar(128)
    declare @idcol nvarchar(128)
    declare @sql nvarchar(max)
    
    --initialize those two values
    set @table = 'YourTable'
    set @idcol = 'some id to recognize the row'
    
    set @sql = 'select ' + @idcol +' , (0'
    
    select @sql = @sql + ' + isnull(datalength([' + name + ']), 1)' 
            from sys.columns where object_id = object_id(@table)
    set @sql = @sql + ') as rowsize from ' + @table + ' order by rowsize         desc'
    
    PRINT @sql
    
    exec (@sql)
    • 13

  3. E eu gostei do acima do Speedcat e estendi-o para listar todas as tabelas com contagens de linhas e bytes totais.

    declare @table nvarchar(128)
declare @sql nvarchar(max)
set @sql = ''
DECLARE tableCursor CURSOR FOR  
SELECT name from sys.tables

open tableCursor
fetch next from tableCursor into @table

CREATE TABLE #TempTable( Tablename nvarchar(max), Bytes int, RowCnt int)

WHILE @@FETCH_STATUS = 0  
begin
    set @sql = 'insert into #TempTable (Tablename, Bytes, RowCnt) '
    set @sql = @sql + 'select '''+@table+''' "Table", sum(t.rowsize) "Bytes", count(*) "RowCnt" from (select (0'

    select @sql = @sql + ' + isnull(datalength([' + name + ']), 1) ' 
        from sys.columns where object_id = object_id(@table)
    set @sql = @sql + ') as rowsize from ' + @table + ' ) t '
    exec (@sql)
    FETCH NEXT FROM tableCursor INTO @table  
end

PRINT @sql

CLOSE tableCursor   
DEALLOCATE tableCursor

select * from #TempTable
select sum(bytes) "Sum" from #TempTable

DROP TABLE #TempTable
    • 5

  4. tente isso:

    ;WITH CTE as(select *,LEN(ISNULL(col1,''))+LEN(ISNULL(col2,'')) as row_len from yourtable)
select * from CTE where row_len > 8060
    • 0

  5. Eu sei que esta é uma pergunta antiga, mas há uma maneira melhor:

    select
    SomeOtherColumn,
    Bytes = datalength((select x.* from (values(null))data(bar) for xml auto))
from Table x
    • 0

relate perguntas