Quais outras informações são armazenadas no cabeçalho da página

Paul Randal realmente responde a essa pergunta exata nos comentários da postagem do blog que você vinculou:

Os 8060 bytes são o tamanho máximo de um registro, não a quantidade de espaço de dados na página – 8096 bytes.

Para um registro de tamanho máximo de 8060 bytes, adicione dois bytes para a entrada da matriz de slot, 10 bytes para um possível backpointer de registro encaminhado de heap, 14 bytes para uma possível tag de controle de versão, e são 26 bytes usados. Os outros 10 bytes são para possível uso futuro.

Se houver mais de um registro na página, todos os 8.096 bytes de espaço de dados poderão ser usados.

Então, respondendo à pergunta no corpo do seu post:

O que esses 36 bytes contêm?

Os 36 bytes "extras" em uma página são usados ​​da seguinte forma:

• 10 bytes reservados para backpointer de registro de encaminhamento de heap
• 14 bytes reservados para a tag de versão apontando para o armazenamento de versão em tempdb
• 12 bytes disponíveis para a matriz de slots
  • no caso de você ter descrito um registro grande, há 10 bytes de espaço "desperdiçado" aqui. Há espaço para mais 5 entradas de matriz de slot de 2 bytes

Apenas para confirmar que a tabela definida na pergunta tem, de fato, 8060 bytes de largura, vamos fazer uma reprodução completa.

Primeiro vamos configurar o banco de dados e a tabela, e inserir uma linha nela. Estou adicionando um índice clusterizado porque os heaps são os piores.

USE master;
GO

CREATE DATABASE PageJunk;
GO

USE PageJunk;
GO

CREATE TABLE [dbo].[Generated_Data_GUID](
    [ID] [int] IDENTITY(1,1) NOT NULL,
    [GUID] [uniqueidentifier] NOT NULL,
    [SEQGUID] [uniqueidentifier] NOT NULL,
    [Data1] [char](4000) NULL,
    [Data2] [char](4000) NULL,
    [Data3] [char](9) NULL,
    [EntryDate] [datetime2](7) NULL
) ON [PRIMARY];
GO

CREATE CLUSTERED INDEX PK_Generated_Data_GUID 
    ON Generated_Data_GUID (ID);
GO

INSERT INTO [dbo].[Generated_Data_GUID]
    ([GUID], SEQGUID, Data1, Data2, Data3, EntryDate)
VALUES
    (NEWID(), NEWID(), REPLICATE('1', 4000), REPLICATE('2', 4000), REPLICATE('3', 9), '2018-01-01');
GO

Podemos ver todas as páginas alocadas ao índice executando este comando DBCC:

DBCC IND ('PageJunk', 'Generated_Data_GUID', 1);
GO

Aquela com um tipo de página 1 é a página de índice (ID de página 336). Podemos despejar todos os tipos de informações sobre essa página com este outro comando DBCC:

DBCC TRACEON (3604); -- needed for the next one to work
GO

DBCC PAGE (PageJunk, 1, 336, 3);
GO

Aqui estão alguns trechos importantes da saída desse comando. Na seção HEADER:

m_freeCnt = 34

Isso significa que há 34 bytes de espaço livre na página. Esses são os 36 que você descreveu em sua postagem original, menos os 2 bytes para a entrada da matriz de slot. Falando nisso:

m_slotCnt = 1

Isso significa que há apenas um registro nesta página.

Agora, para baixo na seção de registro:

Slot 0 Offset 0x60 Length 8060

Record Type = PRIMARY_RECORD        Record Attributes =  NULL_BITMAP    Record Size = 8060

Isso indica que o único registro armazenado nesta página é de 8060 bytes (que é a soma de todos os tamanhos de armazenamento de tipo de dados mais a sobrecarga de 7 bytes por registro).

Portanto, temos um registro de 8060 bytes de tamanho completo nesta página. No entanto, ainda podemos espremer 34 bytes adicionais nesta página se tentarmos mais.

Por exemplo, eu poderia criar uma tabela com 2015 bytes de largura. Cada linha ocuparia 2015 + 7 (sobrecarga interna) + 2 (matriz de slot) = 2024 bytes na página. Portanto, quatro linhas devem somar 8096 bytes, preenchendo exatamente o espaço restante após o cabeçalho de 96 bytes. Vamos tentar no mesmo banco de dados:

CREATE TABLE [dbo].[QuarterPage](
    [ID] [int] IDENTITY(1,1) NOT NULL,
    [GUID] [uniqueidentifier] NOT NULL,
    [SEQGUID] [uniqueidentifier] NOT NULL,
    [Data1] [char](981) NULL,
    [Data2] [char](981) NULL,
    [Data3] [char](9) NULL,
    [EntryDate] [datetime2](7) NULL
) ON [PRIMARY];
GO

CREATE CLUSTERED INDEX PK_QuarterPage
    ON QuarterPage (ID);
GO

INSERT INTO [dbo].[QuarterPage]
    ([GUID], SEQGUID, Data1, Data2, Data3, EntryDate)
VALUES
    (NEWID(), NEWID(), REPLICATE('1', 981), REPLICATE('2', 981), REPLICATE('3', 9), '2018-01-01');
GO 4

Agora encontramos nossa página, e há apenas uma como esperado:

DBCC IND ('PageJunk', 'QuarterPage', 1);
GO

Então agora queremos obter informações na página 352:

DBCC PAGE (PageJunk, 1, 352, 3);
GO

E aqui estão as coisas boas:

m_slotCnt = 4
m_freeCnt = 0

Sem espaço livre! Esta página está cheia com nossas 4 linhas.