coluna sys.objects [Tipo] valor estranho 'ST'

Bem, eu não sei o que ST significa, mas com base na convenção de nomenclatura eu teria que adivinhar que é algum tipo de estatística gerada pelo sistema.

Você pode verificar se existe, por acaso, algum tipo de texto associado ao objeto se for um módulo, por exemplo:

SELECT OBJECT_DEFINITION(613577224);

SELECT definition FROM sys.all_sql_modules
  WHERE object_id = 613577224;

Você também pode tentar:

EXEC sp_help N'dbo._ST_OEA33...';

Por fim, você pode tentar descobrir esse objeto com força bruta em qualquer uma das visualizações do catálogo. Esse script tenta localizar qualquer exibição que contenha uma linha em que a object_idcoluna seja igual a esse valor.

CREATE TABLE #v(v sysname);

DECLARE @sql nvarchar(max) = N'', @obj int = 613577224;

SELECT @sql += N'INSERT #v 
    SELECT DISTINCT ''sys.' + name + N''' 
      FROM sys.' + QUOTENAME(name) + N' 
      WHERE [object_id] = @obj;'
  FROM sys.all_views AS v
  WHERE EXISTS 
  (
    SELECT 1 
      FROM sys.all_columns AS c
      WHERE c.name = N'object_id' 
      AND c.[object_id] = v.[object_id]
  ); 

EXEC sys.sp_executesql @sql, N'@obj int', @obj;

SELECT v FROM #v;

DROP TABLE #v;

Se isso não resultar em nada, você poderá expandi-lo para incluir intcolunas baseadas em todas as exibições de catálogo, pois às vezes object_idos valores são armazenados em colunas com nomes diferentes, como referenced_major_idou parent_object_id, e quaisquer resultados aqui também podem fornecer pistas.

SET NOCOUNT ON;

CREATE TABLE #v(v sysname);

DECLARE @sql nvarchar(max) = N'', @obj int = 613577224;

SELECT @sql += N'INSERT #v 
    SELECT DISTINCT ''sys.' + v.name + N''' 
      FROM sys.' + QUOTENAME(v.name) + N' 
      WHERE ' + QUOTENAME(c.name) + N' = @obj;'
  FROM sys.all_views AS v
  INNER JOIN sys.all_columns AS c
  ON v.[object_id] = c.[object_id]
  WHERE v.[schema_id] = 4
    AND c.[system_type_id] IN (56,127)
    AND v.name NOT IN (N'syscolumns')
    AND v.name NOT LIKE N'dm_fts_%'; 

EXEC sys.sp_executesql @sql, N'@obj int', @obj;

SELECT v FROM #v;

GO
DROP TABLE #v;

Objetos ST são estatísticas de uso da tabela de banco de dados. Ontem, eu estava em uma situação em que precisávamos excluir um esquema completamente em uma instância gerenciada de SQL do Azure . Ao tentar descartar o esquema, não conseguimos fazer isso e obtivemos alguns erros longos como ST__xxxxxx___Chinesechars..... A razão para isso é que as tabelas que foram descartadas agora não pertenciam mais a um esquema e suas estatísticas ainda existiam no Tabelas de sistema de instância gerenciada.

Você tem 2 opções. Tente descartar as estatísticas antes de descartar a tabela usando:

DROP STATISTICS [Database].[Schema].[Table];

Ou mova as estatísticas para outro esquema. Não é o melhor, mas o ajudará a contornar o erro ao descartar um esquema.

ALTER SCHEMA [SchemaToMoveTo] TRANSFER OBJECT::[SchemaFrom].[ST__xxxxxx___Chinesechars]

Parece ser um bug nas instâncias gerenciadas do SQL.