Início / dba / Perguntas / 185018
Accepted
Mazhar
Asked: 2017-09-05 03:07:08 +0800 CST

Como alterar dinamicamente o banco de dados usando TSQL

  • 772

Estou tendo problemas ao tentar alterar dinamicamente o contexto do SSMS para o banco de dados especificado no SQL dinâmico:

EXEC sys.sp_executesql N'USE db1 ' ;

Ele é executado com sucesso, mas o contexto do banco de dados do SSMS não muda.

Eu tentei uma pequena modificação no acima assim

DECLARE @sql NVARCHAR(100) DECLARE @db NVARCHAR(50)
SET @db = N'db1' SET @sql = N'Use ' + @db
EXEC sp_executesql @sql

Novamente, ele é executado com sucesso, mas o banco de dados não muda.

sql-server t-sql

3 respostas

  1. Best Answer

    O SSMS NÃO VAI, REpito, NÃO MUDARÁ PARA O CONTEXTO DE UM COMANDO DE USO QUE VOCÊ EXECUTA EM SQL DINÂMICO.

    Se o objetivo final é executar algum outro SQL dinâmico dentro do banco de dados escolhido, isso é bastante fácil:

    DECLARE @db sysname = N'db1';

DECLARE @exec nvarchar(max) = QUOTENAME(@db) + N'.sys.sp_executesql',
        @sql  nvarchar(max) = N'SELECT DB_NAME();';

EXEC @exec @sql;

    Se precisar passar parâmetros, não tem problema:

    DECLARE @db sysname = N'db1', @i int = 1;

DECLARE @exec nvarchar(max) = QUOTENAME(@db) + N'.sys.sp_executesql',
        @sql  nvarchar(max) = N'SELECT DB_NAME(), @i;';

EXEC @exec @sql, N'@i int', @i;

    Se o objetivo é executar algum SQL estático dentro do banco de dados escolhido, talvez você deva considerar armazenar esse SQL estático em um procedimento armazenado em cada banco de dados e chamá-lo dinamicamente assim:

    DECLARE @db sysname = N'db1';

DECLARE @exec nvarchar(max) = QUOTENAME(@db) + N'.sys.sp_executesql',
        @sql  nvarchar(max) = N'EXEC dbo.procedurename;';

EXEC @exec @sql;

    E espero que o objetivo final não seja executar todo esse código no SSMS apenas para que o SSMS esteja agora no contexto de @db... Daniel gostaria muito se eu declarasse explicitamente que isso não é possível, como o comentário de @Lothar também afirmou.

    • 19

  2. O dynamicSQL nãoéexecutado especificamente em linha com o resto do seu códigoéuma entidade separada (mesmo que seja executado como se estivesse em linha

    Se você executar o código: SET @sql = N'Use ' + @db + '; select DB_NAME(); select @@spid'no lugar do seu conjunto atual, você notará que os resultados que retornam indicam que você moveu o banco de dados ativo, mas ainda está executando na mesma conexão.

    Se você deseja alterar a seleção do banco de dados in-line, a melhor maneira é fazer algo assim:

    IF @db = 'db1'
    USE db1
ELSE IF @db = 'db2'
    USE db2

    Não é bom ou limpo e requer duas linhas por banco de dados em potencial, mas fará o trabalho (não o execute em SQL dinâmico ou você ainda acabará com o mesmo problema do thread principal não ser alterado)

    Observe que o uso de comandos USE é proibido em procedimentos/funções

    • 3

  3. Há um procedimento sp_MSforeachdb não documentado:

    DECLARE @TSQL nvarchar(2000)

SET @TSQL = '
IF ''?'' like ''mydbset-%''
BEGIN
   USE [?];
   PRINT ''********** database: [?] ************''
   select count(*) from information_schema.tables; -- ANY SQL or SP Call in database
END
'
-- Executing TSQL for each database
EXEC sp_MSforeachdb @TSQL
    • -2

relate perguntas