Início / dba / Perguntas / 175411
Accepted
Malvineous
Asked: 2017-06-06 01:12:21 +0800 CST

CONVERT() retorna lixo com CLOBs no Oracle

  • 772

Estou procurando reparar uma tabela de dados no Oracle, de preferência via SQL sem privilégios, que teve dados UTF-8 inseridos em um banco de dados UTF-8, usando o conjunto de caracteres Latin-1 por engano.

O símbolo β GREEK SMALL LETTER BETAdeveria ter entrado no banco de dados, mas em vez disso os dois caracteres βforam... como os dois caracteres UTF-8 Î LATIN CAPITAL LETTER I WITH CIRCUMFLEXseguidos por ² SUPERSCRIPT TWO.

Este código de exemplo demonstra o problema e a correção, mas só funciona com VARCHARcolunas. Assim que a CLOBé usado, a conversão falha:

-- This must return AL32UTF8 for this example to be valid
SELECT VALUE FROM NLS_DATABASE_PARAMETERS WHERE PARAMETER='NLS_CHARACTERSET';

CREATE TABLE EXAMPLE (T VARCHAR2(20));
INSERT INTO EXAMPLE (T) VALUES ('Example β');
SELECT T FROM EXAMPLE; -- Should return 'Example β'
SELECT CONVERT(T, 'WE8ISO8859P1') FROM EXAMPLE;
UPDATE EXAMPLE SET T=CONVERT(T, 'WE8ISO8859P1');
SELECT T FROM EXAMPLE; -- Should return 'Example β', problem fixed
DROP TABLE EXAMPLE;

No entanto, se o VARCHAR2(20)for alterado para CLOB, isso não funcionará mais. CONVERT()retorna caracteres de lixo. Eu posso usar TO_CHAR()para contornar o problema, mas eventualmente recebo um erro que CLOBtem mais de 4000 caracteres, então TO_CHAR()falha.

Existe uma maneira de fazer o exemplo acima funcionar, ao usar uma CLOBcoluna com mais de 4000 caracteres?

oracle character-set

1 respostas

  1. Best Answer

    DBMS_LOBpacote também tem funções de conversão. Infelizmente, não há suporte para converter CLOB em CLOB e alterar o conjunto de caracteres em uma etapa, então os dados são convertidos primeiro em BLOB e depois de volta em CLOB.

    CREATE TABLE EXAMPLE (T CLOB);
INSERT INTO EXAMPLE (T) VALUES ('Example β ');

begin
  for i in 1..12
  loop
    update example set t = t || t;
  end loop;
  commit;
end;
/

select dbms_lob.getlength(t) from example;

DBMS_LOB.GETLENGTH(T)
---------------------
                45056

    Agora a parte da conversão:

    create or replace function repair_data (p_clob clob) return clob as
  l_blob blob; 
  l_dest_offset number := 1;
  l_src_offset number := 1;
  l_lang_context number := 0;
  l_warning number;
  l_result clob;
begin
  dbms_lob.createtemporary(l_blob, true, dbms_lob.call);
  dbms_lob.createtemporary(l_result, true, dbms_lob.call);
  dbms_lob.converttoblob(l_blob, p_clob, dbms_lob.lobmaxsize, l_dest_offset, l_src_offset,
                         nls_charset_id('WE8ISO8859P1'), l_lang_context, l_warning);
  l_dest_offset := 1;
  l_src_offset := 1;
  l_lang_context := 0;
  dbms_lob.converttoclob(l_result, l_blob, dbms_lob.lobmaxsize, l_dest_offset, l_src_offset,
                         nls_charset_id('AL32UTF8'), l_lang_context, l_warning);
  return l_result;
end;
/

select repair_data(T) from example;

REPAIR_DATA(T)                          
----------------------------- 
Example β Example β Example β ...

update example set t = repair_data(t);
...
    • 5

relate perguntas