SQL Server - exporta tabelas para arquivos XML

Este trabalho pode ser feito usando o utilitário BCP.

Pré-requisitos:

1. Você precisaria configurar seu servidor, para habilitar xp_cmdshell:

   EXEC master.dbo.sp_configure 'show advanced options', 1
   RECONFIGURE
   EXEC master.dbo.sp_configure 'xp_cmdshell', 1
   RECONFIGURE
   

2. Permissões, qual conta xp_cmdshellestá sendo executada?

   xp_cmdshell 'whoami' 
   

3. Crie uma nova pasta, onde você salvará os arquivos, e conceda acesso total nesta pasta ao usuário do passo 2.

Eu recomendo que você tente primeiro com algumas tabelas, adicione um TOPcritério à seleção do cursor, apenas para verificar se esse script funciona bem em seu servidor.

select TOP 3 TABLE_CATALOG, TABLE_SCHEMA, TABLE_NAME
from INFORMATION_SCHEMA.Tables 
where TABLE_TYPE = 'BASE TABLE';

Basicamente, o script obtém uma lista de tabelas de INFORMATION_SCHEMAe executa o utilitário BCP para cada elemento da lista.

Os arquivos XML serão nomeados como:DATABASE_SCHEMA_TABLE.XML

Este é o script completo, antes de executá-lo, substitua os <...>valores incluídos de acordo com a configuração do seu sistema:

use <your_database>
go

declare @ServerInstance nvarchar(50),
        @Database sysname, 
        @Schema sysname,
        @Table sysname, 
        @RootFolder nvarchar(165),
        @BcpParams nvarchar(100),
        @cmdBCP nvarchar(500),
        @FQI varchar(600),
        @FileName varchar(600),
        @retExec int;

    set @ServerInstance = '<server\instance>';
    set @BcpParams = '-t -T -w';
    set @RootFolder = '<folder_name>';


    declare curXml cursor fast_forward for
        select TABLE_CATALOG, TABLE_SCHEMA, TABLE_NAME
        from INFORMATION_SCHEMA.Tables 
        where TABLE_TYPE = 'BASE TABLE';

    open curXml;
    fetch next from curXml into @Database, @Schema, @Table

    while @@FETCH_STATUS = 0
    begin

        set @FQI = @Database + '.' + @Schema + '.' + @Table;
        set @FileName = @RootFolder + @Database + '_' + @Schema + '_' + @Table + '.xml';

        select @cmdBCP = ' bcp "SELECT * FROM '
                         + @FQI 
                         + ' row FOR XML AUTO, ROOT(''' + @Table + '''), elements"'
                         + ' queryout "' + @FileName + '" '
                         + @BcpParams
                         + ' -S ' + @ServerInstance;

        print @cmdBCP;

        EXEC @retExec = xp_cmdshell @cmdBCP;

        if @retExec <> 0
        begin
            close curXml;
            deallocate curXml;
            raiserror('BCP Error', 16, 1);
        end

        fetch next from curXml into @Database, @Schema, @Table;
    end

    close curXml;
    deallocate curXml;