Início / dba / Perguntas / 14890
Accepted
Pankaj
Asked: 2012-03-13 21:17:01 +0800 CST

Declarando o cursor para fazer um loop sobre alguns valores no SQL Server 2008 R2

  • 772

Eu tenho algumas unidades de negócios, como Índia, Internacional, EUA, Reino Unido.

Eu tenho que:

  1. Crie uma variável de tabela (tabela de memória virtual) com colunas que correspondam ao SP_Reportconjunto de resultados do procedimento armazenado
  2. Declare um cursor que contém todas as unidades de negócios e, em seguida, o cursor deve percorrer as BU's
  3. Para cada BU, execute um procedimento armazenado chamado SP_Reporte insira os dados na variável da tabela
  4. Finalmente tenho que selecionar as colunas da variável da tabela + timestamp + BU, inseri-las em outra tabela e limpar a variável da tabela.

Código:

declare @K table (BU nvarchar(max), K nvarchar(max),Y money, A money, D money, YP money)
declare @FY int
declare @BU nvarchar(max)

INSERT INTO @K (BU, K, Y, A, D, YP) 
    EXEC dbo.SP_Report '2012', 'India'

SELECT * FROM @K

Este código retorna o resultado da variável de tabela. Agora eu tenho que usar o cursor, que eu não sei como. Como posso resolver o mesmo.

sql-server-2008 cursors

4 respostas

  1. Best Answer

    O tópico MSDN/BOL para DECLARE CURSOR contém sintaxe de exemplo para uso do cursor. Dito isto, como eu tinha 5 minutos de folga no trem esta manhã...

    -- Create temporary table for Business Units (replace with the "real" table)
DECLARE @BusinessUnit TABLE (BU NVARCHAR(MAX))

INSERT @BusinessUnit
SELECT 'India' UNION SELECT 'International' UNION SELECT 'US' UNION SELECT 'UK'

DECLARE @K TABLE (BU NVARCHAR(MAX),K NVARCHAR(MAX),Y MONEY,A MONEY,D MONEY,YP MONEY)
DECLARE @FY INT
DECLARE @BU NVARCHAR(MAX)

SET @FY = 2012

DECLARE BU_cursor CURSOR FAST_FORWARD FOR
SELECT BU FROM @BusinessUnit

OPEN BU_cursor
FETCH NEXT FROM BU_cursor INTO @BU

WHILE @@FETCH_STATUS = 0
BEGIN
    INSERT @K (BU, K, Y, A, D, YP)
    EXEC dbo.SP_Report @FY, @BU

    FETCH NEXT FROM BU_cursor INTO @BU
END

CLOSE BU_cursor
DEALLOCATE BU_cursor

SELECT * FROM @K
    • 9

  2. Você pode dar um passo adiante e fazer a consulta interna executar sql dinâmico, algo assim:

    DECLARE @BusinessUnit TABLE (BU NVARCHAR(MAX))
DECLARE @cmd varchar(222)
INSERT @BusinessUnit
SELECT 'India' UNION SELECT 'International' UNION SELECT 'US' UNION SELECT 'UK'

--DECLARE @K TABLE (BU NVARCHAR(MAX),K NVARCHAR(MAX),Y MONEY,A MONEY,D MONEY,YP MONEY)
DECLARE @FY INT
DECLARE @BU NVARCHAR(MAX)

SET @FY = 2012

DECLARE BU_cursor CURSOR FAST_FORWARD FOR
SELECT BU FROM @BusinessUnit

OPEN BU_cursor
FETCH NEXT FROM BU_cursor INTO @BU
WHILE @@FETCH_STATUS = 0
BEGIN
DECLARE @K TABLE (BU NVARCHAR(MAX),K NVARCHAR(MAX),Y MONEY,A MONEY,D MONEY,YP MONEY)
    --INSERT @K (BU, K, Y, A, D, YP)
    --EXEC dbo.SP_Report @FY, @BU

    SET @cmd = 'INSERT '+@K+' (BU, K, Y, A, D, YP)'+
    ' SELECT '+@BU+','+@BU+',456,78,99,11111'
    EXEC sp_sqlexec @cmd
    FETCH BU_cursor INTO @BU
END
CLOSE BU_cursor
DEALLOCATE BU_cursor

SELECT * FROM @K
    • 2

  3. Eu acho que é o melhor exemplo para entender o CURSOR facilmente ..

    Usando o cursor no SQL Server

    • 0

  4. exemplo simples para entender os cursores:

    DECLARE @CustomerID as INT;
declare @msg varchar(max)
DECLARE @BusinessCursor as CURSOR;

SET @BusinessCursor = CURSOR FOR
SELECT CustomerID FROM Customer WHERE CustomerID IN ('3908745','3911122','3911128','3911421')

OPEN @BusinessCursor;
    FETCH NEXT FROM @BusinessCursor INTO @CustomerID;
    WHILE @@FETCH_STATUS = 0
        BEGIN
            SET @msg = '{
              "CustomerID": "'+CONVERT(varchar(10), @CustomerID)+'",
              "Customer": {
                "LastName": "LastName-'+CONVERT(varchar(10), @CustomerID) +'",
                "FirstName": "FirstName-'+CONVERT(varchar(10), @CustomerID)+'",    
              }
            }|'
        print @msg
    FETCH NEXT FROM @BusinessCursor INTO @CustomerID;
END
    • 0

relate perguntas