ALTER DATABASE MODIFY FILEGROUP [myfilegroup] AUTOGROW_ALL_FILES

Complementando as respostas de Max e Kenneth ..

Sugiro que você aplique o SQL Server 2016 CU1 , pois há um bug conhecido com a AUTOGROW_ALL_FILESpropriedade -

A propriedade não é preservada após a reinicialização do banco de dados ou do servidor. A exibição sys.filegroups ainda mostra que a coluna correspondente para a propriedade (is_autogrow_all_files e is_read_only) está definida como 1. No entanto, não é realmente eficaz.

Além disso, é importante observar que no SQL Server 2016 você não precisa do TF 1117 , pois is_autogrow_all_filesé equivalente ao TF1117

sys.filegroupscontém uma coluna is_autogrow_all_filesque indica se a configuração já está ativada para o grupo de arquivos em questão.

Isso deve mostrar uma lista de instruções de alteração de banco de dados que você pode executar:

DECLARE @cmd NVARCHAR(2000);
DECLARE cur CURSOR LOCAL FORWARD_ONLY STATIC 
FOR
SELECT '
select ''ALTER DATABASE ' + QUOTENAME(d.name) + ' MODIFY FILEGROUP '' + QUOTENAME(ds.name) + '' AUTOGROW_ALL_FILES;''
from ' + QUOTENAME(d.name) + '.sys.data_spaces ds
    INNER JOIN ' + QUOTENAME(d.name) + '.sys.filegroups fg ON ds.data_space_id = fg.data_space_id
WHERE fg.is_autogrow_all_files = 0;
'
FROM sys.databases d;
OPEN cur;
FETCH NEXT FROM cur INTO @cmd;
WHILE @@FETCH_STATUS = 0
BEGIN
    PRINT (@cmd);
    FETCH NEXT FROM cur INTO @cmd;
END
CLOSE cur;
DEALLOCATE cur;

O código exibirá um conjunto de instruções que você pode executar para cada banco de dados na instância, para modificar cada grupo de arquivos.

E o exemplo da instrução gerada é:

select 'ALTER DATABASE [msdb] MODIFY FILEGROUP ' + QUOTENAME(ds.name) + ' AUTOGROW_ALL_FILES;'
from [msdb].sys.data_spaces ds
    INNER JOIN [msdb].sys.filegroups fg ON ds.data_space_id = fg.data_space_id
WHERE fg.is_autogrow_all_files = 0;

O SSMS 17.8 introduziu o suporte à interface do usuário para esse recurso. A partir do SSMS 17.8 já está disponível :

Nesta versão do SQL Server Management Studio, introduzimos o suporte de script e interface do usuário para a propriedade de grupo de arquivos do banco de dados AUTOGROW_ALL_FILES .

Essa propriedade foi introduzida no SQL Server 2016 para substituir o sinalizador de rastreamento 1117, mas só era configurável por meio do script T-SQL. Agora você pode definir a propriedade por meio de uma caixa de seleção na página Propriedades do banco de dados -> Grupos de arquivos

^{Fonte da imagem: https://cloudblogs.microsoft.com/uploads/prod/2018/06/image-1-sql-server.png}

Você também pode usar o botão “Script” para fazer o script da mudança:

USE [AdventureWorks2016_EXT] 

GO

declare @autogrow bit 

SELECT @autogrow=convert(bit, is_autogrow_all_files) 
  FROM sys.filegroups WHERE name=N'PRIMARY' 

if(@autogrow=0) 

ALTER DATABASE [AdventureWorks2016_EXT] 
  MODIFY FILEGROUP [PRIMARY] AUTOGROW_ALL_FILES 

GO

A configuração é por grupo de arquivos. Você pode procurar em sys.filegroups.

SELECT is_autogrow_all_files, * FROM sys.filegroups

sys.filegroupsBol: https://msdn.microsoft.com/en-us/library/ms187782.aspx

Aqui está minha solução para o problema de obter um crescimento de arquivo uniforme em todos os arquivos do banco de dados:

SET NOCOUNT ON 
DECLARE @db_name sysname, @sql NVARCHAR(max)='', @Mainsql NVARCHAR(max)='', @rowCount int

SELECT @Mainsql = @@VERSION
--SELECT @Mainsql 
--Microsoft SQL Server 2008 R2 (SP3) - 10.50.6529.0 (X64)   Mar 19 2015 13:19:13   Copyright (c) Microsoft Corporation  Developer Edition (64-bit) on Windows NT 6.1 <X64> (Build 7601: Service Pack 1) (Hypervisor) 
--Microsoft SQL Server 2016 (SP1) (KB3182545) - 13.0.4001.0 (X64)   Oct 28 2016 18:17:30   Copyright (c) Microsoft Corporation  Developer Edition (64-bit) on Windows Server 2012 R2 Standard 6.3 <X64> (Build 9600: ) 

IF @Mainsql NOT LIKE '%SQL Server 2016%' BEGIN
    SELECT 'This script does not work on servers prior to SQL Server 2016. Please check before continuing'
    SELECT @Mainsql
END

Begin TRY
    DROP TABLE #h
END TRY
BEGIN CATCH
END CATCH
CREATE TABLE #h (i INT IDENTITY(1,1), sqltxt NVARCHAR(max))
DELETE FROM #h

DECLARE dbcursor CURSOR FAST_FORWARD READ_ONLY FOR 
    SELECT name FROM sys.databases 
    WHERE is_read_only=0 AND state_desc='ONLINE' 
    AND source_database_id is NULL AND name NOT IN ('master', 'model', 'msdb')
    ORDER BY name

OPEN dbcursor

FETCH NEXT FROM dbcursor INTO @db_name

WHILE @@FETCH_STATUS = 0
BEGIN
    RAISERROR (' %s' , 10, 1, @db_name) WITH NOWAIT
    SET @rowCount=0
    SELECT @Mainsql =''
    SELECT @Mainsql += '
    SELECT @rowCount=count(*)
    FROM [' + @db_name + '].sys.filegroups F 
    WHERE type <> ''FD''  /* no FILESTREAM_DATA_FILEGROUP */
    AND type <> ''FX'' /* no MEMORY_OPTIMIZED_DATA_FILEGROUP */
    AND is_autogrow_all_files=0
    '
    BEGIN TRY
        EXEC sys.sp_executesql @Mainsql, N'@rowCount int output', @rowCount OUTPUT
    END TRY
    BEGIN CATCH
        RAISERROR ('Unable to access %s' , 10, 1, @db_name) WITH NOWAIT
        RAISERROR ('SQL: %s' , 10, 1, @Mainsql) WITH NOWAIT
    END CATCH

    --SELECT @Mainsql AS max, @rowCount rowcnt

    IF @rowCount <> 0 BEGIN
        SELECT @sql += 'INSERT INTO #h ( sqltxt ) SELECT ''PRINT'''''' + ''[' + @db_name + ']''''''
        ' 
        SELECT @sql += 'INSERT INTO #h ( sqltxt ) SELECT ''USE '' + ''[' + @db_name + ']''
        ' 
        IF @db_name <>'tempdb' BEGIN 
            SELECT @sql += 'INSERT INTO #h ( sqltxt )
            SELECT ''ALTER DATABASE [' + @db_name + '] SET SINGLE_USER WITH ROLLBACK IMMEDIATE;''
            '
        END 
        SELECT @sql += 'INSERT INTO #h ( sqltxt )
        SELECT ''ALTER DATABASE [' + @db_name + '] MODIFY FILEGROUP ['' + fg.name + ''] AUTOGROW_ALL_FILES''
        FROM [' + @db_name + '].sys.filegroups FG 
        WHERE FG.type <> ''FD''  /* no FILESTREAM_DATA_FILEGROUP */
        AND FG.type <> ''FX'' /* no MEMORY_OPTIMIZED_DATA_FILEGROUP */
        AND FG.is_autogrow_all_files=0
        '

        IF @db_name <>'tempdb' BEGIN 
            SELECT @sql += 'INSERT INTO #h ( sqltxt )
            SELECT ''ALTER DATABASE [' + @db_name + '] SET MULTI_USER;''
            '
        END 
    END 
    --SELECT @sql 
    FETCH NEXT FROM dbcursor INTO @db_name
END

SELECT @sql
EXEC sp_executesql @sql

CLOSE dbcursor
DEALLOCATE dbcursor

SELECT @sql=''
SELECT @sql+=sqltxt + '
' FROM #h H 
ORDER BY i
SELECT @sql
--EXEC sp_executesql @sql

Ainda tem problemas; se não houver arquivos em um grupo de arquivos, recebo uma mensagem de erro.

Espero que isso possa ajudar. Às vezes, a execução não será bem-sucedida quando estiver sendo usada por outras pessoas. Você pode executá-lo novamente ou adicionar um script para definir o banco de dados para o modo único.

-- Run the results of this query, It will create queries for all databases in the server.

DECLARE @command varchar(1000) 
SELECT @command = 'use [?]; SELECT ''ALTER DATABASE ? MODIFY FILEGROUP ['' + b.groupname + ''] AUTOGROW_ALL_FILES;'' 
FROM dbo.sysfiles a (NOLOCK)
JOIN dbo.sysfilegroups b (NOLOCK) ON a.groupid = b.groupid
GROUP BY b.groupname'

EXEC sp_MSforeachdb @command