Início / dba / Perguntas / 137200
Accepted
GWR
Asked: 2016-05-03 04:12:13 +0800 CST

Aparar espaços em branco à direita, tabulação, nova linha, retornos de carro, etc.

  • 772

Estou trabalhando com o SQL Server 2008 e estou procurando uma função como ltrime rtrimque também remova guias iniciais e finais, espaços duplos, retornos de carro, alimentações de linha, etc.

Existem várias funções por aí, mas todas as que encontrei têm limitações, por exemplo, truncar a string para 8.000 caracteres. por exemplo (de acordo com alguns dos comentários):

SQL SERVER – 2008 – Função TRIM() aprimorada – Remover espaços à direita, espaços iniciais, espaço em branco, tabulações, retornos de carro, feeds de linha

Um dos comentários propôs uma solução melhor, mas - 1causa um incorrect syntaxerro e não sei por quê.

CREATE FUNCTION dbo.SuperTrimLeft(@str varchar(MAX)) RETURNS varchar(MAX)
    AS
    BEGIN
    IF (ASCII(LEFT(@str, 1)) < 33) BEGIN
        SET @str = STUFF(@str, 1, PATINDEX('%[^'+CHAR(0)+'-'+CHAR(32)+']%', @str) – 1, ' ');
    END;

    RETURN @str;
END;

Então, minha pergunta é: qual é a melhor abordagem para realizar a tarefa acima?

sql-server functions

4 respostas

  1. Best Answer

    A melhor maneira provavelmente seria criar uma função CLR e usar bibliotecas .NET Framework.

    Uma tentativa de TSQL está abaixo.

    DECLARE @Pattern NVARCHAR (50) = N'%[^' + 
/*List from http://stackoverflow.com/a/18169122/73226 */
NCHAR(0x0009) +  /*tab*/
NCHAR(0x000A) +  /*line feed*/
NCHAR(0x000B) +  /*line tabulation*/
NCHAR(0x000C) +  /*form feed*/
NCHAR(0x000D) +  /*carriage return*/
/*Various spaces from https://www.cs.tut.fi/~jkorpela/chars/spaces.html */
NCHAR(0x0020) +  
NCHAR(0x00A0) +  
NCHAR(0x1680) +  
NCHAR(0x180E) +  
NCHAR(0x2000) +  
NCHAR(0x2001) +  
NCHAR(0x2002) +  
NCHAR(0x2003) +  
NCHAR(0x2004) +  
NCHAR(0x2005) +  
NCHAR(0x2006) +  
NCHAR(0x2007) +  
NCHAR(0x2008) +  
NCHAR(0x2009) +  
NCHAR(0x200A) +  
NCHAR(0x200B) +  
NCHAR(0x202F) +  
NCHAR(0x205F) +  
NCHAR(0x3000) +  
NCHAR(0xFEFF) +
N']%' COLLATE Latin1_General_100_BIN2;

WITH T(String) AS
(
SELECT '         leading only' union all
SELECT '

Line breaks

' union all
SELECT '    tab and space    ' union all
SELECT '' 
)
SELECT '[' + SUBSTRING(String,Start,len(String + '..') - Start - Finish) + ']'
FROM T
CROSS APPLY
(
SELECT  PATINDEX(@Pattern,String),
        PATINDEX(@Pattern,REVERSE(String))
)ca(Start, Finish)

    Os delimitadores [e ]são aplicados apenas para facilitar a verificação de que não há espaço em branco escondido ali. Remova-os quando estiver satisfeito, este é o caso.

    • 6

  2. Um dos comentários propôs uma solução melhor, mas o -1 causa um erro de sintaxe incorreto e não sei por quê.

    Porque você copiou e colou do site e a página não mostra um hífen/menos, mas um traço .

    Você pode simplesmente posicionar o cursor atrás dele e excluí-lo, digitar menos no teclado e o código funcionará.

    Se você deseja modificar o código dos comentários para também executar o cenário de corte correto, pode fazer como o artigo e criar uma função que apenas inverte a string duas vezes (código copiado do artigo, mas alterado para usar SuperTrimLeft).

    CREATE FUNCTION dbo.RTrimX(@str VARCHAR(MAX)) RETURNS VARCHAR(MAX)
AS
BEGIN
DECLARE @trimchars VARCHAR(10)
SET @trimchars = CHAR(9)+CHAR(10)+CHAR(13)+CHAR(32)
IF @str LIKE '%[' + @trimchars + ']'
SET @str = REVERSE(dbo.SuperTrimLeft(REVERSE(@str)))
RETURN @str
END
GO
CREATE FUNCTION dbo.TrimX(@str VARCHAR(MAX)) RETURNS VARCHAR(MAX)
AS
BEGIN
RETURN dbo.SuperTrimLeft(dbo.RTrimX(@str))
END
GO
    • 4

  3. As duas respostas dadas até agora envolvem pelo menos uma inversão da corda para atacar o lado direito.

    Este método não.

    CREATE FUNCTION dbo.LTrimWhitespace(@Input VARCHAR(MAX))
RETURNS VARCHAR(MAX)
AS
BEGIN
    DECLARE @Output VARCHAR(MAX)
    DECLARE @Whitespace VARCHAR(20)
    DECLARE @Pos INT

    SET @Whitespace = CHAR(0) + CHAR(9) + CHAR(10) + CHAR(13) + CHAR(32)
    SET @Pos = 1

    WHILE CHARINDEX(SUBSTRING(@Input, @Pos, 1), @Whitespace) > 0
    BEGIN
        SET @Pos = @Pos + 1
    END

    SET @Output = RIGHT(@Input, LEN(@Input) - @Pos + 1)

    RETURN @Output
END

CREATE FUNCTION dbo.RTrimWhitespace(@Input VARCHAR(MAX))
RETURNS VARCHAR(MAX)
AS
BEGIN
    DECLARE @Output VARCHAR(MAX)
    DECLARE @Whitespace VARCHAR(20)
    DECLARE @Pos INT

    SET @Whitespace = CHAR(0) + CHAR(9) + CHAR(10) + CHAR(13) + CHAR(32)
    SET @Pos = LEN(@Input)

    WHILE CHARINDEX(SUBSTRING(@Input, @Pos, 1), @Whitespace) > 0
    BEGIN
        SET @Pos = @Pos - 1
    END

    SET @Output = LEFT(@Input, @Pos)

    RETURN @Output
END
    • 4

  4. A resposta aceita não lida com strings contendo apenas caracteres de quebra de linha.

    Aqui está uma função que lida com isso adequadamente, com base na solução de Martin.

    -- Based on https://dba.stackexchange.com/questions/137200/trim-trailing-whitespace-tab-newline-carriage-returns-etc/137203#137203
CREATE OR ALTER FUNCTION [dbo].[ufn_trim]
(
    @text nvarchar(max)
)
RETURNS nvarchar(max)
AS
BEGIN

    DECLARE @pattern nvarchar(50) = 
        N'%[^'

        -- common white space
        + nchar(0x0009) -- tab
        + nchar(0x000a) -- line feed (lf)
        + nchar(0x000b) -- line tabulation
        + nchar(0x000c) -- form feed
        + nchar(0x000d) -- carriage return (cr)
        + nchar(0x0020) -- space (sp)
        + nchar(0x00a0) -- no-break space (nbsp)

        -- uncommon spaces
        --+ nchar(0x1680) -- ogham space mark
        --+ nchar(0x180e) -- mongolian vowel separator (mvs)
        --+ nchar(0x2000) -- en quad
        --+ nchar(0x2001) -- em quad
        --+ nchar(0x2002) -- en space
        --+ nchar(0x2003) -- em space
        --+ nchar(0x2004) -- three-per-em space
        --+ nchar(0x2005) -- four-per-em space
        --+ nchar(0x2006) -- six-per-em space
        --+ nchar(0x2007) -- figure space
        --+ nchar(0x2008) -- punctuation space
        --+ nchar(0x2009) -- thin space
        --+ nchar(0x200a) -- hair space
        --+ nchar(0x202f) -- narrow no-break space (nnbsp)
        --+ nchar(0x205f) -- medium mathematical space (mmsp)
        --+ nchar(0x3000) -- ideographic space

        + N']%' COLLATE latin1_general_100_bin2
    ;

    DECLARE 
        @start int = PATINDEX(@pattern, @text),
        @end int = PATINDEX(@pattern, REVERSE(@text))
        ;

    IF @start = 0
    BEGIN
        -- the string doesn't contain any non-space character
        RETURN '';
    END

    RETURN SUBSTRING(@text, @start, LEN(@text + '..') - @start - @end);
END
GO
    • 0

relate perguntas