Início / dba / Perguntas / 131247
Accepted
jpmc26
Asked: 2016-03-04 19:05:32 +0800 CST

Determinar a estrutura do cursor de saída

  • 772

Eu tenho uma função no Oracle que nem eu nem minha equipe escrevemos e é fortemente ofuscada. No entanto, ele possui um parâmetro de saída do cursor. Como posso descobrir o número e os tipos que o cursor contém?

Para um exemplo do que preciso, considere este cursor:

DECLARE
  TEMP1 VARCHAR2(500);
  TEMP2 NUMBER;
  TEMP3 RAW(16);
  TEMP SYS_REFCURSOR;
  PROCEDURE MAKE_TEMP(TEMP_RETURN OUT SYS_REFCURSOR) IS
  BEGIN
    OPEN TEMP_RETURN FOR SELECT DUMMY, 5, HEXTORAW('111') FROM DUAL;
  END;
BEGIN
  MAKE_TEMP(TEMP);
  LOOP
    FETCH TEMP INTO TEMP1, TEMP2, TEMP3;
    EXIT WHEN (TEMP%NOTFOUND);
    DBMS_OUTPUT.PUT_LINE('1: '||TEMP1);
    DBMS_OUTPUT.PUT_LINE('2: '||TO_CHAR(TEMP2));
    DBMS_OUTPUT.PUT_LINE('3: '||RAWTOHEX(TEMP3));
  END LOOP;
  CLOSE TEMP;
END;
/

Se MAKE_TEMPfosse a função que estou tentando usar, precisaria saber que ela tem 3 valores por linha e que os valores são a VARCHAR2, a NUMBERe a RAWnessa ordem para que eu possa definir variáveis ​​para armazenar os resultados.

Estou usando o Oracle 11.2.0.1.0, embora eu agradeça se também existam respostas para versões mais recentes.

Por que não posso simplesmente olhar para a fonte

Se você precisa saber, a função faz parte do Oracle ASP.NET Membership Provider e foi escrita pela Oracle. Estou tentando depurar um problema e gostaria de ver o que esta função está retornando. O código-fonte da função começa assim:

create or replace 
FUNCTION  "ORA_ASPNET_MEM_GETALLUSERS" wrapped
0
abcd
abcd
abcd
abcd
abcd
abcd
abcd
abcd
abcd
abcd
abcd
abcd
abcd
abcd
abcd
3
8
9200000
1
4
0
33

Como você pode ver, será (na melhor das hipóteses) extremamente difícil extrair qualquer informação sobre o cursor disso.

oracle oracle-11g-r2

1 respostas

  1. Best Answer

    Este código de exemplo mostra como analisar um arquivo ref_cursor. Existem colunas adicionais disponíveis, consulte a definição de SYS.DBMS_SQL.desc_tab2para obter uma lista completa de colunas disponíveis.

    Neste exemplo, my ref_cursoré definido como select * from user_tables. É claro que você substituiria por conta própria ref_cursor.

    DECLARE
   l_csrid       INTEGER;
   l_coldesc     SYS.DBMS_SQL.desc_tab2;
   l_colcnt      INTEGER;
   l_refcursor   SYS_REFCURSOR;

   FUNCTION tostring (p_label   IN VARCHAR2
                     , p_value   IN VARCHAR2)
      RETURN VARCHAR2
   AS
   BEGIN
      RETURN RPAD (p_label, 30)
             || ': '
             || p_value
             || UTL_TCP.crlf;
   END tostring;

   PROCEDURE myput_line (p_rec      IN DBMS_SQL.desc_rec2
                       , p_colnum   IN INTEGER)
   AS
   BEGIN
      DBMS_OUTPUT.put_line (   RPAD ('_', 30, '_') 
                        || UTL_TCP.crlf
                        || tostring (p_label => 'Column'
                                   , p_value => p_colnum)
                        || tostring (p_label => 'Name'
                                   , p_value => p_rec.col_name)
                        || tostring (p_label => 'Type'
                                   , p_value => p_rec.col_type)
                        || tostring (p_label => 'Null OK'
                                   , p_value => CASE WHEN p_rec.col_null_ok
                                                     THEN 'Yes' 
                                                     ELSE 'No' 
                                                END));
   END myput_line;
 BEGIN
   OPEN l_refcursor FOR
      SELECT * FROM user_tables;

   l_csrid   := DBMS_SQL.to_cursor_number (rc => l_refcursor);
   DBMS_SQL.describe_columns2 (c       => l_csrid
                             , col_cnt => l_colcnt
                             , desc_t  => l_coldesc);

   FOR i IN 1 .. l_colcnt LOOP
      myput_line (l_coldesc (i), i);
   END LOOP;
END;
    • 3

relate perguntas