Esfregando nomes por meio de consulta/lote SQL

Eu tive que fazer isso por motivos de NPI (informações não públicas) em um empregador anterior. Acabou embaralhando os campos em um script, já que um par nome / sobrenome não é NPI, a menos que esteja vinculado a outra coisa.

Aqui está uma versão aproximada do script. Tempere a gosto. Além disso, isso pressupõe que você tenha nomes e sobrenomes em campos separados.

CREATE TABLE #RandomData
(
    DataID int not null,
    ID int not null,
    FirstName varchar(50),
    LastName varchar(50)
)

INSERT INTO #RandomData (ID, DataID)
SELECT ROW_NUMBER() OVER (ORDER BY NEWID()), DataId FROM DataTable

UPDATE r SET r.FirstName = x.FirstName
FROM #RandomData r
INNER JOIN (
    SELECT ROW_NUMBER() OVER (ORDER BY NEWID()) AS ID, FirstName FROM DataTable
) x
    ON x.ID = r.ID

UPDATE r SET r.LastName = x.LastName
FROM #RandomData r
INNER JOIN (
    SELECT ROW_NUMBER() OVER (ORDER BY NEWID()) AS ID, LastName FROM DataTable
) x
    ON x.ID = r.ID

CREATE CLUSTERED INDEX PK_RandomData ON #RandomData
(
    DataID asc
)

ALTER TABLE DataTable DISABLE TRIGGER ALL

UPDATE dt 
    SET dt.FirstName = r.FirstName, 
    dt.LastName = r.LastName
FROM DataTable dt
INNER JOIN #RandomData r
    ON dt.DataId = r.DataId

ALTER TABLE DataTable ENABLE TRIGGER ALL

DROP TABLE #RandomData

Se você não deseja saber qual é o nome, mas por qualquer motivo deseja manter algo na tabela para esse registro, pode sempre usar apenas um hash do nome :

UPDATE MyTable
SET Name = HASHBYTES('SHA1', Name)

Isso manterá um valor exclusivo para cada registro de nome, mas você não terá como saber qual é o nome. Você pode, no entanto, ver se um nome corresponde a um valor comparando uma entrada hash com o hash armazenado.

Hashes criptográficos como este são uma maneira, então você pode criar um hash idêntico a partir de uma string de entrada idêntica, mas não determinar a string de entrada, mesmo que você saiba qual é o hash.

Sim, graças a esta função, nome e sobrenome como Jack Sparrow se tornará Dchv Dkiokmd e e-mail como [email protected] se tornará [email protected] :

-------------------------------------------------

--A view to give you Random Values
CREATE VIEW dbo.random(value) AS SELECT RAND();

GO
-------------------------------------------------

--Randomization Procedure
CREATE FUNCTION dbo.fnRandomizedText (
@OldValue AS VARCHAR(MAX)
)RETURNS VARCHAR(MAX)

BEGIN

  DECLARE @NewValue AS VARCHAR(MAX)
  DECLARE @nCount AS INT
  DECLARE @cCurrent AS CHAR(1)
  DECLARE @cScrambled AS CHAR(1)
  DECLARE @Random AS REAL
 
  SET @NewValue = ''
  SET @nCount = 0
   WHILE (@nCount <= LEN(@OldValue))
  BEGIN
    SELECT @Random = value FROM random
    SET @cCurrent = SUBSTRING(@OldValue, @nCount, 1)
     IF ASCII(@cCurrent) BETWEEN ASCII('a') AND ASCII('z')
       SET @cScrambled = CHAR(ROUND(((ASCII('z') - ASCII('a') - 1) * @Random + ASCII('a')), 0))
    ELSE IF ASCII(@cCurrent) BETWEEN ASCII('A') AND ASCII('Z')
       SET @cScrambled = CHAR(ROUND(((ASCII('Z') - ASCII('A') - 1) * @Random + ASCII('A')), 0))
    ELSE IF ASCII(@cCurrent) BETWEEN ASCII('0') AND ASCII('9')
       SET @cScrambled = CHAR(ROUND(((ASCII('9') - ASCII('0') - 1) * @Random + ASCII('0')), 0))
    ELSE
       SET @cScrambled = @cCurrent

    SET @NewValue = @NewValue + @cScrambled
    SET @nCount = @nCount + 1

  END
   RETURN LTRIM(RTRIM(@NewValue))
END
GO 
-------------------------------------------------

Você pode então atualizar suas tabelas assim.

UPDATE my_Users_table SET UserName = dbo.fnRandomizedText(UserName), LoweredUserName = dbo.fnRandomizedText(LoweredUserName)