No Microsoft Word, como você continua um número de página de um documento diferente - e não de uma seção diferente no mesmo documento

Dê uma olhada no meu artigo no site Microsoft Answers: Usando RD e outros campos

( https://answers.microsoft.com/en-us/msoffice/forum/all/using-rd-and-other-fields-to-construct-multi-file/f1c8cd3c-c92d-4dc3-bfb7-84773c8b4dce )

Ele cita extensivamente uma cópia de arquivo de um artigo de Jonathan West.

Infelizmente, o que provavelmente aconteceu é que os números das páginas de cada documento começam na página 1, então o Índice parece uma verdadeira bagunça com os números das páginas começando novamente em cada documento. Você provavelmente deseja que as páginas sejam numeradas consecutivamente ao longo do documento. Se o arquivo da página de rosto incluindo o sumário tiver 5 páginas, você deseja que o capítulo1.doc comece na página 6.

Fazer isso manualmente é complicado, mas pode ser feito se você não tiver muitos arquivos separados. Abra capítulo1.doc e vá para Inserir/Números de página. A seguinte caixa de diálogo aparecerá.

Imagem da caixa de diálogo Números de página.

Clique no botão Formatar e a seguinte caixa de diálogo aparecerá.

Imagem da caixa de diálogo Formato de número de página, que é uma extensão da caixa de diálogo Número de página, mostrando a opção selecionada para continuar na seção anterior.

Clique no botão Iniciar em e digite 6 na caixa à direita dele (ou o que você quiser como número da página inicial) e clique em OK para fechar a caixa de diálogo. A caixa de diálogo Números de página terá mudado para agora ter esta aparência. (Observação: o botão Cancelar agora é um botão Fechar.)

A imagem da caixa de diálogo Número da página novamente, agora mostrando que o botão Cancelar foi alterado para um botão Fechar.

Clique em Fechar para limpar a caixa de diálogo. Não clique em OK, pois isso inserirá números de página no cabeçalho. Presumo que os números das páginas já estejam lá e você não precisa de outro conjunto!

Agora você precisa ir até o final do documento para descobrir o número da última página. Anote, você precisará dele para definir a página inicial do próximo capítulo. Agora salve e feche o capítulo1.doc.

Em seguida, você abre Chapter2.doc e repete todo o processo, adicionando 1 ao número da última página do capítulo atual, para definir a página inicial do próximo capítulo. Depois de ler todos os capítulos, você poderá atualizar o Índice novamente e, desde que não tenha cometido erros em nenhum lugar, os números das páginas no sumário serão todos corrigidos.

Como você pode ver, este é um processo um tanto trabalhoso se você tiver mais de 2 ou 3 documentos no conjunto. Felizmente, este processo é um candidato ideal para um pouco de automação; e só para facilitar a sua vida, escrevi a macro que faz isso. (O código para isso também está na Biblioteca TechTrax, se você quiser baixá-lo e importá-lo diretamente para o seu modelo.)

Sub UpdateTocAndPageNumbers()
Dim oField As Field
Dim strCode As String
Dim iLastPage As Long
Dim oDoc As Document

ChDir ActiveDocument.Path
With ActiveDocument.ActiveWindow.View
    .ShowAll = False
    .ShowHiddenText = False
    .ShowFieldCodes = False
    .Type = wdPrintView
End With
ActiveDocument.Repaginate
Selection.Move unit:=wdStory, Count:=1
iLastPage = Selection.Information(wdActiveEndAdjustedPageNumber)

For Each oField In ActiveDocument.Fields
    If oField.Type = wdFieldRefDoc Then
        strCode = Trim$(oField.Code)
        strCode = Trim$(Mid$(strCode, InStr(strCode, " ")))
        If LCase$(Left$(strCode, 2)) = "\f" Then
            strCode = Trim$(Mid$(strCode, 3))
        End If
        If LCase$(Right$(strCode, 2)) = "\f" Then
            strCode = Trim$(Left$(strCode, Len(strCode) - 2))
        End If
        If Asc(strCode) = 34 Then
            strCode = Trim$(Mid$(strCode, 2, Len(strCode) - 2))
        End If

        ChDir ActiveDocument.Path
        Set oDoc = Documents.Open(FileName:=strCode)
        oDoc.Activate
        With oDoc.ActiveWindow.View
            .ShowAll = False
            .ShowHiddenText = False
            .ShowFieldCodes = False
            .Type = wdPrintView
        End With
        oDoc.Sections(1).Headers(wdHeaderFooterPrimary). _
                 PageNumbers.RestartNumberingAtSection = True
        oDoc.Sections(1).Headers(wdHeaderFooterPrimary). _
                 PageNumbers.StartingNumber = iLastPage + 1
        oDoc.Repaginate
        Selection.Move unit:=wdStory, Count:=1
        iLastPage = Selection.Information(wdActiveEndAdjustedPageNumber)
        oDoc.Close SaveChanges:=wdSaveChanges
    End If
Next oField
ChDir ActiveDocument.Path
ActiveDocument.Fields.Update
End Sub

Você executa esta macro quando o documento da página de rosto está aberto. Ele faz o seguinte:

Define o documento para que o texto oculto e os códigos de campo não sejam exibidos. Isso garante que os números das páginas exibidos na tela correspondam ao que será impresso.

Repagina o documento da página de rosto e descobre o número da última página.

Encontra cada campo RD por vez. Para cada campo ele faz o seguinte: a. abre o documento associado, b. define a página inicial com o valor apropriado, c. repagina o documento, d. descobre o número da página da última página, e. salva e fecha o documento. Quando todos os campos RD forem processados, ele atualiza os campos no documento da folha de rosto, incluindo o Índice.

Talvez seja necessário executar esta macro duas vezes, inicialmente. Isso ocorre porque o processo de atualização do Índice pode alterar o número de páginas do documento de capa.

A macro funcionará mesmo para o Word 97, onde você não tem a opção \f nas opções de campos RD. Se for esse o caso, deverá ter todos os documentos do conjunto na mesma pasta. Eu recomendo que você faça isso, de qualquer maneira