Início / coding / Perguntas / 79597426
Accepted
Dorkhan C.
Asked: 2025-04-29 08:15:33 +0800 CST

Como posso contar o número de colunas que têm pelo menos uma célula onde o número é maior que 0?

  • 772
Ano um b c
2017 0 1 3
2018 0 3 0
2019 0 0 0

Considerando a tabela acima, qual é uma fórmula do Excel que me ajude a contar quantas colunas têm pelo menos uma célula maior que 1? Gostaria de ter uma fórmula que funcionasse se eu tivesse 1.000 colunas.

Neste caso, a resposta deve ser 2 (colunas b e c).

Eu estava tentando usar diferentes combinações de COUNTIFS e SUM, mas não encontrei a correta. Até agora tentei

=SUM(--(MAX(B2:B4)>1), --(MAX(C2:C4)>1), --(MAX(D2:D4)>1))

Isso funciona, mas não é viável com 1000 colunas.

excel

3 respostas

  1. Coloque a fórmula da desigualdade booleana dentro do argumento de matriz de BYCOL:

    =SUM(--BYCOL(B2:D4 > 0, OR))

    insira a descrição da imagem aqui

    • 4

  2. Também existe uma maneira mais convencional de obter totais de colunas, que se aplica a muitas versões do Excel:

    =SUM(N(MMULT(COLUMN(B2:D4),N(B2:D4>0))>0))

    (pode usar o número da coluna como um multiplicador em vez de 1 porque não importa exatamente quais são os totais da coluna, desde que sejam diferentes de zero).

    • 3
  3. Best Answer

    Se você tiver o Excel 365, poderá fazer isso dividindo seus dados em colunas individuais e verificando as colunas uma de cada vez:

    Detalhado:

    =LET(
    data, B2:E4,
    colHasValue, BYCOL(data, LAMBDA(col, MAX(col) > 0))*1,
    SUM(colHasValue)
)

    Compactar:

    =SUM(BYCOL(B2:E4, LAMBDA(col, MAX(col) > 0))*1)

    para versões anteriores do Excel você pode usar:

    =SUM(IF(FREQUENCY(IF(B2:E4>0, COLUMN(B2:E4)), COLUMN(B2:E4)) > 0, 1))
    • 2

relate perguntas