Início / coding / Perguntas / 79594519
Accepted
HSHO
Asked: 2025-04-27 07:32:56 +0800 CST

Como transpor valores agrupados próximos a datas dinamicamente no Planilhas Google?

  • 772

Tenho um conjunto de dados no Planilhas Google onde as datas aparecem na Coluna A e os valores (como nomes de itens) aparecem na Coluna B.

Os dados são assim:

UM B
01/04/2024 Item A
Item B
Item C
05/04/2024 Item D
Item E
4/10/2024 Item F
Item G
Item H
Item I

Quero transpor os nomes dos itens horizontalmente ao lado de cada data —
ou seja, cada data terá seus valores correspondentes distribuídos nas Colunas C, D, E, etc.

Resultado esperado:

UM B C D E
01/04/2024 Item A Item B Item C
05/04/2024 Item D Item E
4/10/2024 Item F Item G Item H Item I

Tentei usar fórmulas como FILTER, TRANSPOSE, e ARRAYFORMULA,
mas só consigo obter resultados para o primeiro encontro ou resultados incompletos.

Como posso preencher dinamicamente todas as linhas conforme o resultado esperado?

De preferência usando uma fórmula, não scripts ou tabelas dinâmicas manuais.

Eu tentei, mas esta fórmula não é precisa

=IF(A2<>"", TRANSPOSE(FILTER(B$2:B, MMULT(N(ROW(A$2:A$1000)<=ROW(A2))*(A$2:A<>""), SEQUENCE(COLUMNS(B$2:B),1,1,0))=1)), "")

Desde já, obrigado!

google-sheets

2 respostas

  1. Você pode usar

    =LET(
   dates, A2:A,
   items, B2:B,
   dates.fill, SCAN(, dates, LAMBDA(a, c, IF(c="", a, c))),
   MAP(
     UNIQUE(TOCOL(dates, 1)),
     LAMBDA(date, {date, TOROW(FILTER(items, dates.fill = date), 1)})
   )
 )

    Como funciona

    Primeiro, preenchemos cada célula em branco na coluna de datas com a data anterior não vazia usando SCANe atribuímos o resultado à variáveldates.fill

    dates.fill ← SCAN(, dates, LAMBDA(a, c, IF(c="", a, c)))

    Em seguida, iteramos sobre cada um datena coluna de datas usando a MAPfunção e retornamos a data empilhada horizontalmente para os itens filtrados com base na condição dates.fill = dateusando a FILTERfunção

    MAP(
  UNIQUE(TOCOL(dates, 1)),
  LAMBDA(date, {date, TOROW(FILTER(items, dates.fill = date), 1)})
)
    • 2
  2. Best Answer

    Você pode tentar:

    =LET(a, A:B,
     b, INDEX(a, , 1),
     c, INDEX(a, , 2),
     d, SCAN("", b, LAMBDA(x, y, IF(y="", x, y))),
     e, UNIQUE(d),
     BYROW(e, LAMBDA(x, HSTACK(x, TOROW(FILTER(c, d=x), 1)))))

    SAÍDA

    UM B C D E
    01/04/2024 Item A Item B Item C
    05/04/2024 Item D Item E
    4/10/2024 Item F Item G Item H Item I

    REFERÊNCIAS

    • 1

relate perguntas