Início / coding / Perguntas / 79592765
Accepted
grsousajunior
Asked: 2025-04-25 22:53:12 +0800 CST

A caixa de cores do Gnuplot aparece em branco quando invertida usando certos terminais

  • 772

Estou enfrentando um problema estranho ao gerar um gráfico usando gnuplot(versão 6.0 patchlevel 1, no Microsoft Windows versão 10.0.19045.5737). No meu gráfico, preciso que ele colorboxapareça invertido, ou seja, o gradiente de cores deve ir de valores altos na parte inferior para valores baixos na parte superior.

Notei que ao usar certos terminais, o colorboxaparece completamente em branco ou em branco, sem o gradiente de cor esperado:

  1. wxt, sucesso
  2. emf, sucesso
  3. pngcairo, sucesso
  4. svg, sucesso
  5. pdfcairo, FALHAR
  6. epscairo, FALHAR

Anexei imagens de exemplo:

saída do pngcairoterminal

saída do terminal pngcairo

saída do pdfcairoterminal

saída do terminal pdfcairo

Saída usando a opção "Exportar gráfico para arquivo" como pdf na wxtjanela interativa.

pdf da janela interativa wxt

Aqui está uma versão simplificada do script que estou usando:

reset session
set encoding utf8

#set terminal wxt size 800,400 font "Arial,9"

#set terminal pngcairo size 800,400 font "Arial,9"
#set output "diagram.png"

set terminal pdfcairo size 10,5 in font "Arial,14"
set output "diagram.pdf"

set tics out nomirror
unset key
set style circle radius graph 0.01
set style fill transparent solid 1 border lc ls -1
set palette viridis maxcolors 25
set xrange [400:450]
set yrange [100:600]
set xlabel "Temperature/°C"
set ylabel "Index"
set cblabel "Depth (m)"
set cbtics offset -1,0

set multiplot layout 1,2

set title "normal colorbox"
plot "data.txt" u 2:3:1 w circle lc palette

set colorbox invert
set title "inverted colorbox"
replot

unset multiplot
unset output

Parece data.txtalgo assim:

Depth   Temp    Index
201.05  427.34  251.70
205.24  431.39  296.30
209.24  414.27  185.66
211.89  432.81  140.98
215.54  413.30  299.13
217.17  424.50  272.27
221.00  426.93  184.91
221.50  420.06  241.14
222.95  420.16  467.74
223.60  410.67  196.70
226.39  416.30  166.96
228.87  430.30  437.81
232.22  415.00  343.18
232.23  415.76  494.67
235.17  410.02  224.60
238.31  429.06  302.89
238.37  414.77  367.09
238.49  421.26  195.13
239.36  414.16  161.46
241.46  418.85  263.24
242.76  431.97  378.32
243.17  420.91  154.06
246.77  421.16  135.39
247.30  414.63  411.32
248.97  410.22  146.30

Há algo errado com meu script/dados ou isso é um bug?

pdf

2 respostas

  1. Best Answer

    Posso confirmar o problema relatado e o rastreei até o commit 84e724843f (aplicado entre as versões 6.0-rc1 e 6.0-rc2). Este bug deve afetar apenas os terminais qt e cairo. A correção é simples, mas infelizmente não vejo uma solução alternativa para ela na versão 6.0 atual.

    • 2

  2. Só por diversão, aqui está uma solução alternativa para as versões 6.0.x, que também funciona para qtterminais pdfcairoe, no entanto, ao custo da perda do escalonamento automático. O que você pode fazer é:

    • inverter a paleta viaset palette negative
    • defina o cbrange e o cbtics (semi-)manualmente
    • espelhar os dados no cbrange

    Roteiro:

    ### invert colorbox for qt,pdfcairo terminal in gnuplot 6.0.x
reset session

# create some random test data
set table $Data
    plot '+' u (rand(0)*50+400):(rand(0)*500+100):(rand(0)*50+200) w table
unset table

set xrange[400:450]
set yrange[100:600]
set key noautotitle
set palette viridis maxcolors 25
set palette negative

cbmin  = 200
cbmax  = 250
cbstep = 10
set cbrange [cbmin:cbmax]
set for [i=0:(cbmax-cbmin)/cbstep] cbtics add (sprintf("%g",cbmax-i*cbstep) cbmin+i*cbstep)
mirror(col) = cbmax + cbmin - column(col)

plot $Data u 1:2:(mirror(3)) w p pt 7 lc palette
### end of script

    Resultado: (do gnuplot 6.0.2 e do terminal qt)

    insira a descrição da imagem aqui

    • 0

relate perguntas