Início / coding / Perguntas / 79587580
Accepted
ulrichson
Asked: 2025-04-23 06:59:37 +0800 CST

Fórmula de matriz do Google Sheets para lógica booleana com base em números duplicados por célula

  • 772

Eu tenho um column Aque parece com:

11

11 11
5 6
5 5
5 6 6 5
11 11 11 11

6 7 8
3
3 2 3

e buscando uma maneira alternativa e mais inteligente de produzir TRUE/ FALSEconforme mostrado aqui:

resultado desejado
11 verdadeiro
FALSO
11 11 verdadeiro
5 6 FALSO
5 5 verdadeiro
5 6 6 5 verdadeiro
11 11 11 11 verdadeiro
FALSO
6 7 8 FALSO
3 verdadeiro
3 2 3 verdadeiro

A lógica é:

  • FALSEse

    • a célula está vazia
    • não há números duplicados por célula

  • TRUEse

    • a célula tem apenas um número
    • a célula tem dois ou mais números duplicados, independentemente da ordem

Mais notas:

  • os números são separados por espaço
  • os números podem variar de 1 a 80
  • cada célula pode conter no máximo 40 números separados por espaço
  • cada célula pode conter no mínimo 1 número ou estar vazia

Como posso resolver isso:

Posso somar (de várias maneiras - LAMBDA, QUERY(SUBSTITUTE(, SUM(SPLIT(, ...) e dividir por contagem. Se o resultado for um número inteiro TRUE, é , se o resultado tiver casas decimais, é , FALSEmas isso não funcionará para 3 2 3, 6 7 8.

Outra maneira seria dividi-lo e usar QUERYe contar números por linha, agrupar por row_numbers e pivotar por all_numbers, e LETentão envolvê-lo em IFe remover números menores que 2. Em seguida, combiná-lo com TRIM(TOCOL(QUERY(TRANSPOSE(e LEN. Então IF, como >0está, TRUEe adicionar o restante da lógica para casos não cobertos por QUERY.

A fórmula seria enorme de qualquer maneira, então estou procurando uma maneira "mais inteligente/curta" (se houver). Talvez haja algum padrão mágico de expressão regular com o qual eu não esteja familiarizado?

google-sheets

1 respostas

  1. Best Answer

    Supondo que os dados estejam em A2:A, você pode usar a seguinte fórmula B2e arrastá-la para baixo.

    =ARRAYFORMULA(LET(s,IFERROR(SPLIT(A2," ")),OR(COUNTA(s)=1,COUNTIF(s,s)>1)))

    Ou com uma única fórmula em B2:

    =ARRAYFORMULA(
   BYROW(
     IFERROR(SPLIT(A2:INDEX(A:A,MATCH(,0/LEN(A:A)))," ")),
     LAMBDA(s,OR(COUNTA(s)=1,COUNTIF(s,s)>1))
   )
 )

    Como funciona

    Primeiro, dividimos a string pelo espaço e atribuímos o resultado as

    s ← IFERROR(SPLIT(A2," "))

    Em seguida, usamos o OR functionpara retornar TRUEse a string dividida tiver apenas um valor ou tiver pelo menos um valor que ocorre mais de uma vez

    OR(COUNTA(s)=1,COUNTIF(s,s)>1)
    • 4

relate perguntas