Início / coding / Perguntas / 79582871
Accepted
nickC
Asked: 2025-04-20 06:26:57 +0800 CST

Encontre a diferença de dias entre duas datas do Reino Unido no formulário de usuário VBA

  • 772

Essas datas são produzidas pelo calendário de Trevor Eyre no formato dos EUA, então converti para o Reino Unido para meus usuários. No entanto, acho que é por isso que não consigo encontrar a diferença de data, já que não é mais um número. Existe uma maneira?

Private Sub TextBox6_Enter()
'CALENDAR arrival date
    Dim dateVariable As Date
    dateVariable = CalendarForm.GetDate
    Dim sDate As String 'changes format from USA for UK users
    sDate = Format(dateVariable, "dd-mmm-yy")
    TextBox6.value = sDate
End Sub
Private Sub TextBox7_Enter()
'CALENDAR date leave
    Dim dateVariable As Date
    dateVariable = CalendarForm.GetDate
    Dim sDate As String
'changes format from USA to UK
    sDate = Format(dateVariable, "dd-mmm-yy")
    TextBox7.value = sDate
End Sub
  Private Sub TextBox20_change()
'Number of NIGHTS
     TextBox20.value = DateDiff("d", DateValue(TextBox6.value), TextBox7.value)
End Sub

Depois de vários dias, percebi que sDate estava repetido nas caixas de texto 6 e 7. Com 77, meu cérebro está confuso. Agora funciona perfeitamente. Obrigado `Private Sub TextBox6_Enter() ' CALENDAR data de chegada

Dim dateVariable As Date
dateVariable = CalendarForm.GetDate
TextBox6.value = dateVariable

sDate = Format(dateVariable, "dd/mm/aaaa") 'muda o formato dos EUA para o Reino Unido TextBox6.value = sDate 'entrada na caixa de texto End Sub

Private Sub TextBox7_Enter() 'Data de saída do CALENDÁRIO

Dim dateVariable As Date
dateVariable = CalendarForm.GetDate
TextBox7.value = dateVariable

tDate = Format(dateVariable, "dd/mm/aaaa") 'altera o formato dos EUA para o Reino Unido TextBox7.value = tDate

TextBox20.Text = DateDiff("d", TextBox6.value, TextBox7.value) Fim do Sub```

vba

3 respostas

  1. Claro, mas certifique-se de que está comparando coisas semelhantes e que ambas as datas estejam no mesmo formato. Por exemplo:

    Sub CompareDates()

    Dim sUS   As String
    Dim sUK   As String
    Dim dtUS  As Date
    Dim dtUK  As Date

    sUS = "12/1/2025"
    sUK = "2/12/2025"
    
    parts = Split(sUS, "/")
    dtUS = DateSerial( _
        CInt(parts(2)), _
        CInt(parts(0)), _
        CInt(parts(1)))

    parts = Split(sUK, "/")
    dtUK = DateSerial( _
        CInt(parts(2)), _
        CInt(parts(1)), _
        CInt(parts(0)))

     Debug.Print DateDiff("d", dtUS, dtUK)

End Sub
    • 0

  2. Converter 'Datas de sequência de caracteres' específicas em datas

    • Usando algumas funções auxiliares, você pode fazer o seguinte:

      TextBox6.Value = DateToUKString(CalendarForm.GetDate)
TextBox7.Value = DateToUKString(CalendarForm.GetDate)
TextBox20.Value = DateDiff( _
    "d", UKStringToDate(TextBox6.Value), UKStringToDate(TextBox7.Value))

    Ajuda

    Function DateToUKString(ByVal InputDate As Date) As String
    DateToUKString = VBA.Format(InputDate, "dd-mmm-yy")
End Function

    Function UKStringToDate(ByVal UKString As String) As Date
    Dim Parts() As String: Parts = VBA.Split(UKString, "-")
    On Error Resume Next
        UKStringToDate = VBA.DateSerial( _
            20 & Parts(2), GetMonthNumber(Parts(1)), Parts(0))
    On Error GoTo 0
End Function

    Function GetMonthNumber(ByVal Mmm As String) As Long
    Dim EngMonths() As Variant: EngMonths = VBA.Array( _
        "jan", "feb", "mar", "apr", "may", "jun", _
        "jul", "aug", "sep", "oct", "nov", "dec")
    Dim lcMonth As String: lcMonth = VBA.LCase(Mmm)
    Dim EngMonth As Variant, i As Long
    For Each EngMonth In EngMonths
        i = i + 1
        If EngMonth = lcMonth Then GetMonthNumber = i: Exit Function
    Next EngMonth
End Function

    Teste

    Sub Test()
    
    Const str1 As String = "12-Feb-24"
    Const str2 As String = "17-May-24"
    
    Debug.Print DateDiff("d", str1, str2)
    Debug.Print DateToUKString(Date)
    Debug.Print DateToUKString(Date + 2100)
    Debug.Print UKStringToDate("") = 0

End Sub

    Resultado

     95 
20-Apr-25
19-Jan-31
True
    • 0
  3. Best Answer

    Use duas variáveis ​​de nível de módulo e você poderá reduzir isso significativamente:

    Option Explicit

Private ArrivalDate As Date
Private LeaveDate   As Date

Private Sub TextBox6_Enter()

    ' CALENDAR arrival date.

    ArrivalDate = CalendarForm.GetDate
    TextBox6.Value = Format(ArrivalDate, "dd-mmm-yy")
    
End Sub

Private Sub TextBox7_Enter()

    ' CALENDAR date leave.
    
    LeaveDate = CalendarForm.GetDate
    TextBox7.Value = Format(LeaveDate, "dd-mmm-yy")
    
End Sub
  
Private Sub TextBox20_change()
    
    ' Number of NIGHTS.
    
    TextBox20.Value = DateDiff("d", ArrivalDate, LeaveDate)
    
End Sub
    • 0

relate perguntas