Terraform for_each sem suporte de bloco dinâmico

Antes de responder a essa pergunta, acho importante esclarecer algumas divergências na terminologia: você chamou sua variável de entrada de "painéis", mas, com base no valor que você atribuiu a ela, isso parece ser uma coleção de pastas , onde cada uma contém um ou mais painéis.

Portanto, acho que o que você realmente precisa é de uma instância de grafana_folderpara cada elemento de var.dashboardse, então, uma instância de grafana_dashboardpara cada painel distinto listado em todas as pastas.

O que você está fazendo aqui é essencialmente uma versão com sabor de Grafana do problema descrito em Achatamento de estruturas aninhadas parafor_each , e então você pode adaptar a abordagem descrita lá da seguinte maneira.

Primeiro, vamos declarar uma variável de entrada para garantir que concordamos sobre seu tipo:

# NOTE: I renamed this just to clarify that it's a collection
# of folders, rather than of dashboards directly. You can
# rename it back if you prefer.
variable "dashboard_folders" {
  type = map(object({
    folder_name = string
    dashboards = set(object({
      file      = string
      overwrite = optional(bool, false)
    }))
  }))
}

Como essa variável já é um mapa e já tem um elemento para cada "pasta" que você deseja declarar, você pode usar esse valor diretamente for_eachpara declarar várias instâncias de grafana_folder:

resource "grafana_folder" "dashboards" {
  for_each = var.dashboard_folders

  uid   = each.key
  title = each.value.folder_name
}

Os painéis em si são mais complexos porque você precisa primeiro projetar essa estrutura de dados em um formato adequado para descrever todos os seus painéis de uma só vez: ela deve ser uma coleção com um elemento por painel , em vez de um elemento por pasta . É aí que flattenentra:

locals {
  dashboards = flatten([
    for folder_key, folder in var.dashboard_folders : [
      for dashboard in folder.dashboards : {
        folder_key = folder_key
        file       = dashboard.file
        overwrite  = dashboard.overwrite
      }
    ]
  ])
}

local.dashboardsagora é uma coleção plana de todos os painéis onde cada um sabe a chave da pasta à qual pertence.

O único requisito restante é projetar isso em um mapa onde cada elemento tenha uma chave exclusiva que o Terraform possa usar para rastrear qual instância de recurso pertence a ele. Se você puder garantir que cada painel definitivamente tenha fileum argumento distinto, isso pode ser adequado, e vou presumir que isso seja verdade para este exemplo, mas se não for, você precisará introduzir outro valor para rastrear exclusivamente cada painel dentro de cada pasta.

resource "grafana_dashboard" "all" {
  for_each = {
    for dashboard in local.dashboards :
    "${dashboard.folder_key}:${dashboard.file}" => dashboard
  }

  folder      = grafana_folder.dashboards[each.value.folder_key].id
  config_json = file(each.value.file)
  overwrite   = each.value.overwrite
}

Isso usa o folder_keyatributo de cada objeto para conectar cada painel de volta ao seu objeto de pasta correspondente e, portanto, isso deve descrever uma hierarquia no Grafana que seja equivalente à hierarquia descrita por var.dashboard_folders.

Isso pode não compilar; no entanto, você pode tentar uma construção semelhante e ver se funciona para suas necessidades. A ideia é nivelar/projetar seus painéis em uma estrutura dashboard_content com um elemento por item dashboards[], juntamente com a chave pai -> folder_name. É importante que folder_name seja único, pois é assim que o recurso será vinculado. O segundo loop une os filhos nivelados ao pai na seção dinâmica.

Nunca tentei vincular um item em uma seção dinâmica a um item em um escopo externo, então não sei com certeza se o loop interno será compilado, mas pode valer a pena tentar.

# This is a flattened projection of var.dashboards . It will contain one entry for each item in dashboards[]
#[
# { folder_name = "Test Folder", file="test.json", overwrite= "true"}
# { folder_name = "Test Folder", file="test1.json", overwrite= "false"}
#]

locals{
  dashboard_contents = flatten([
    for x, dashboard in var.dashboards : [
      for y, dashboard_content in dashboard.dashboards : {      

        folder_name = dashbopard.folder_name,
        file = dashboard_content.file,
        overwrite = dashboard.overwrite
      }
    ]
  ])
}

resource "grafana_dashboard" "dashboards" {
  for_each    = ( for dashboard in var.dashboards : dashboard.folder_name => dashboard}
  folder      = dashboard.folder_name
  dynamic "dashboard" {
    for_each = { for dashboard_contents in local.dashboard_contents : dashboard_contents.file => dashboard_contents if dashboard_contents.folder ==  dashboard.folder_name}       
      content {
        config_json    = file("../../dashboards/${dashboard_contents.file}")
        overwrite      = dashboard_contents.overwrite
      }
  }
}