Início / coding / Perguntas / 79577369
Accepted
Jens
Asked: 2025-04-16 22:08:36 +0800 CST

Como selecionar intervalos de irmãos em XSLT?

  • 772

Suponha que eu tenha o seguinte XML:

<?xml version="1.0" encoding="utf8"?>
<test>
  <list>
    <li>a</li>
    <li>a</li>
    <li begin="true">b</li>  <!-- begin of the "b" list -->
    <li>b</li>
    <li>b</li>
    <li end="true">b</li>  <!-- end of the "b" list -->
    <li>c</li>
    <li>c</li>
  </list>
</test>

e eu queria dividir essa lista em três listas com base nos atributos begine endusando XSLT 1.0, de modo que o resultado seja:

  <list>
    <li>a</li>
    <li>a</li>
  </list>

  <list>
    <li>b</li>
    <li>b</li>
    <li>b</li>
    <li>b</li>
  </list>

  <list>
    <li>c</li>
    <li>c</li>
  </list>

Consegui selecionar a primeira e a terceira lista, mas tive dificuldade em corresponder ao intervalo da lista do meio:

<xsl:template match="list">
  <list>
    <xsl:apply-templates select="li[@begin = 'true']/preceding-sibling::li" />
  </list>
  <list>
    <xsl:apply-templates select="li[...]" />  <!-- Hmm 🤔 -->
  </list>
  <list>
    <xsl:apply-templates select="li[@end = 'true']/following-sibling::li" />
  </list>
</xsl:template>

Tentei várias expressões usando position()and count()mas não consegui acertar.

Adendo: os atributos begine endsão únicos, ou seja, há exatamente um grupo desse tipo na lista original.

xml

4 respostas

  1. Best Answer

    No exemplo dado, com apenas 1 grupo marcado (portanto, apenas 3 grupos no total), você poderia usar:

    <list>
    <xsl:apply-templates select="li[@begin='true']" />
    <xsl:apply-templates select="li[@begin='true']/following-sibling::li[not(preceding-sibling::li[@end='true'])]"/>
</list>

    (Eu dividi isso em duas instruções separadas para facilitar a leitura.)

    Adicionado:

    Se você estiver usando o processador libxslt , poderá aproveitar algumas funções de extensão que ele suporta e fazer:

    <xsl:template match="list">
    <xsl:variable name="head" select="set:leading(li, li[@begin = 'true'])"/>
    <xsl:variable name="tail" select="set:trailing(li, li[@end = 'true'])"/>
    <list>
        <xsl:apply-templates select="$head"/>
    </list>
    <list>
        <xsl:apply-templates select="set:difference(li, $head | $tail)"/>
    </list>
    <list>
        <xsl:apply-templates select="$tail"/>
    </list>
</xsl:template>

    desde que você declare:

    xmlns:set="http://exslt.org/sets"
extension-element-prefixes="set"

    na xsl:stylesheettag inicial.

    • 0

  2. Este xslt retorna o resultado esperado

    ?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
  <xsl:output method="xml" indent="yes"/>
  <xsl:template match="list">
    <list>
      <xsl:for-each select="li[@begin = 'true']/preceding-sibling::li">
        <li>
          <xsl:value-of select="text()"/>
        </li>
      </xsl:for-each>
    </list>

    <list>
      <xsl:for-each select="li[@begin = 'true' or @end = 'true'] | li[following-sibling::li[@end = 'true'] and preceding-sibling::li[@begin = 'true']]">
        <li>
          <xsl:value-of select="text()"/>
        </li>
      </xsl:for-each>
    </list>

    <list>
      <xsl:for-each select="li[@end = 'true']/following-sibling::li">
        <li>
          <xsl:value-of select="text()"/>
        </li>
      </xsl:for-each>
    </list>
  </xsl:template>
</xsl:stylesheet>

    <list>
  <li>a</li>
  <li>a</li>
</list>
<list>
  <li>b</li>
  <li>b</li>
  <li>b</li>
  <li>b</li>
</list>
<list>
  <li>c</li>
  <li>c</li>
</list>
    • 0

  3. No caso geral, isso é bem complicado usando o XSLT 1.0 e é muito melhor migrar para o XSLT 2.0+ se puder, onde você tem instruções como xsl:for-each-group group-starting-with.....

    Muito depende de quão geral é o problema, por exemplo, se você pode ter múltiplos "inícios" e "fim" dentro de uma sequência de irmãos, ou talvez até mesmo começos e fins aninhados. (Lembre-se sempre de que um exemplo não define o seu problema: precisamos conhecer o problema geral, não apenas um exemplo dele.)

    Uma técnica útil (não apenas na versão 1.0, mas também em versões posteriores) é a "recursão entre irmãos", na qual você aplica um apply-templates no primeiro filho, e este aplica um apply-templates no próximo filho, e assim por diante. Há um exemplo disso aqui:

    XSLT 1.0 seleciona todos os nós entre os nós 'flag'

    e você pode encontrar outros pesquisando por "XSLT sibling recursion".

    A marcação que você nos mostrou é um exemplo de "marcação sobreposta" e há uma vasta literatura sobre o assunto: se você tem muito XML como esse, vale a pena se familiarizar com a teoria.

    • 0

  4. Tentei várias expressões usando position() e count(), mas não consegui acertar.

    Poderia ser feito desta forma:

    <xsl:template match="list">
    <xsl:variable name="begin" select="count(li[@begin='true']/preceding-sibling::li) + 1" />
    <xsl:variable name="end" select="count(li[@end='true']/preceding-sibling::li) + 1" />
    <list>
        <xsl:apply-templates select="li[position() &lt; $begin]"/>
    </list>
    <list>
        <xsl:apply-templates select="li[$begin &lt;= position() and position() &lt;= $end]"/>
    </list>
    <list>
        <xsl:apply-templates select="li[$end &lt; position()]"/>
    </list>
</xsl:template>
    • 0

relate perguntas