Início / coding / Perguntas / 79569361
Accepted
BoomDizzle
Asked: 2025-04-12 00:53:10 +0800 CST

awk para extrair um bloco de texto

  • 772

Estou tentando descobrir um comando/script awk para extrair um bloco de texto de um arquivo grande. A subseção do arquivo em que estou interessado é esta:

  Board Info: #512
    Manufacturer: "Dell Inc."
    Product: "0X3D66"
    Version: "A02"
    Serial: "..CN7016343F00IE."
  Chassis Info: #768

As linhas Board Info e Chassis Info têm 2 espaços à esquerda, enquanto o bloco recuado tem 4. Eu gostaria de não presumir que a linha final começa com Chassis Info (pode ser outra coisa) e apenas confiar em chegar à próxima linha começando com 2 espaços.

Esse:

awk '/^\s{2}Board Info/,/^\s{2}[^B ]/' dump.txt

resolve esta instância específica, mas não funcionará se, em vez de 'Informações do chassi', a linha do bloco final começar com a letra B (por exemplo, BOM).

Se eu usar:

awk '/^\s{2}Board Info/,/^\s{2}\S*/' dump.txt

O padrão final também corresponde à linha "Informações do Quadro", então eu obtenho apenas essa linha. Como obtenho esse bloco recuado (4 espaços à esquerda) sem codificar o bloco final (como acima) e depender do padrão final ser "a próxima linha que começa com exatamente 2 espaços à esquerda"?

regex

5 respostas

  1. Supondo que haja apenas linhas recuadas com 4 caracteres de espaço em branco após o início, você pode ter certeza de que há pelo menos uma única linha recuada presente, ou então não imprima nada.

    awk '
  /^\s{2}Board Info/ {
    start = 1; buffer = $0; indent = 0; next
  }
  start && /^\s{4}\S/ {
    buffer = buffer == "" ? $0 : buffer "\n" $0;
    indent = 1;
  }
  start && /^\s{2}\S/ {
    if (indent) {
      print buffer "\n" $0;
    }
    start = 0;
  }
' dump.txt

    Não tenho certeza se você deseja imprimir a linha inicial e a linha de fechamento, mas você pode omitir a impressão delas se quiser, não adicionando-as ao buffer.

    Você pode alterar estas linhas:

    start = 1; buffer = ""; indent = 0; next

    E:

    print buffer;
    • 4
  2. Best Answer

    Eu melhoraria seu código

    awk '/^\s{2}Board Info/,/^\s{2}[^B ]/' dump.txt

    seguindo o caminho, deixe dump.txto conteúdo ser

    undesired text
  Board Info: #512
    Manufacturer: "Dell Inc."
    Product: "0X3D66"
    Version: "A02"
    Serial: "..CN7016343F00IE."
  Other Info: #768
another undesired text
more undesired text

    então

    awk '/^\s{2}Board Info/,/^\s{2}[[:alpha:]]/&&!/^\s{2}Board Info/' dump.txt

    dá saída

      Board Info: #512
    Manufacturer: "Dell Inc."
    Product: "0X3D66"
    Version: "A02"
    Serial: "..CN7016343F00IE."
  Other Info: #768

    Explicação: Alterei a condição final exigindo que a linha começasse com 2 caracteres de espaço em branco seguidos por qualquer caractere alfabético E ( &&) NÃO ( !) sendo a linha de informações do quadro (negando a condição inicial).

    (testado no GNU Awk 5.3.1)

    Como modifico o que você tem para imprimir apenas o bloco recuado?

    Você pode adicionar uma ação que imprimirá se houver (pelo menos) 3 caracteres de espaço em branco no início da linha, seguindo o caminho

    awk '/^\s{2}Board Info/,/^\s{2}[[:alpha:]]/&&!/^\s{2}Board Info/{if(/^\s{3}/){print}}' dump.txt

    que dará a seguinte saída

        Manufacturer: "Dell Inc."
    Product: "0X3D66"
    Version: "A02"
    Serial: "..CN7016343F00IE."
    • 3

  3. Esta awksolução deve funcionar com qualquer versão de awk:

    awk '/^  [^[:blank:]]/ { blk = !blk; next } blk' dump.txt

    Manufacturer: "Dell Inc."
    Product: "0X3D66"
    Version: "A02"
    Serial: "..CN7016343F00IE."

    Explicação:

    • A expressão regular /^ [^[:blank:]]/corresponde a uma linha com 2 espaços no início, seguidos por qualquer caractere que não seja espaço em branco.
    • blk = !blk: alterna o valor do sinalizador blkpara 1ou0
    • blkno final imprime uma linha se blkfor1
    • 3

  4. Usando qualquer awk:

    $ awk '/^  [^ ]/{ f=(/Board Info/); next } f' dump.txt
    Manufacturer: "Dell Inc."
    Product: "0X3D66"
    Version: "A02"
    Serial: "..CN7016343F00IE."

    Em relação ao seu código original:

    awk '/^\s{2}Board Info/,/^\s{2}[^B ]/' dump.txt
    1. Usar expressões de intervalo ( /start/,/end/) costuma ser mais complicado de acertar em geral e sempre mais difícil de aprimorar do que usar uma flag ( fno meu código), o que frequentemente leva a código duplicado ou outros softwares ruins. Veja " Uma expressão de intervalo /start/,/end/ é útil no awk?" para mais informações.
    2. Somente o GNU awk reconheceria isso \scomo uma abreviação para [[:space:]]isso, o que torna seu código não portátil, mas ambas as construções são desnecessárias de qualquer maneira quando seus espaços são apenas caracteres em branco.
    • 3

  5. Um pequeno ajuste FSé tudo o que você precisa para um 1/0indicador de impressão sem usar intervalos de padrões:

    echo '
  Board Info: #512
    Manufacturer: "Dell Inc."
    Product: "0X3D66"
    Version: "A02"
    Serial: "..CN7016343F00IE."
  Chassis Info: #768' |

    awk '_^_ < NF ? _ = !! index($!NF, " Board Info:") : !_ < NF' FS='^  [A-Z]'

         1    Board Info: #512
     2      Manufacturer: "Dell Inc."
     3      Product: "0X3D66"
     4      Version: "A02"
     5      Serial: "..CN7016343F00IE."
    • 1

relate perguntas