Início / coding / Perguntas / 79565732
Accepted
Ezio
Asked: 2025-04-10 12:42:20 +0800 CST

CONT.SE usando apenas DATA e critérios de correspondência de nome

  • 772

Recebi a tarefa de contabilizar quantos leads um agente de vendas recebe por dia. Então, criei uma planilha, onde os dados são preenchidos automaticamente a partir de uma plataforma de CRM, e uma aba separada para o rastreador.

Eu uso dois critérios para contagens: a data e o nome do agente. Não tenho problema com o nome do agente. O único problema é a DATA.

O problema é que Countif não conta células porque não consegue corresponder à minha referência de célula (somente data), enquanto nos dados de leads ele contém data e hora.

Além disso, os dados dos leads precisam estar em uma aba separada. Não posso combinar as duas abas, elas devem ficar ocultas e bloqueadas, pois os dados são preenchidos automaticamente por uma plataforma de CRM.

Criei uma planilha semelhante como exemplo. Aqui está o link: https://docs.google.com/spreadsheets/d/1-kEKHCQk1qF_k8oPnu-166fYdHukozfChEQ4bixwwB0/edit?usp=sharing

Qualquer orientação ou ajuda sobre isso é apreciada.

date

3 respostas

  1. Use query(), assim:

    =query(
  'Leads Data'!A1:B,
  "select Col2, count(Col2) 
   where Col2 is not null
   group by Col2
   pivot toDate(Col1)",
  1
)

    Veja query() .

    • 1

  2. Você pode tentar esta fórmula

    =BYCOL(B$1:E$1, LAMBDA(date, ARRAYFORMULA(IF(A2:A13="", "", COUNTIFS('Leads Data'!$B:$B, A2:A13, 'Leads Data'!$A:$A, ">="&date, 'Leads Data'!$A:$A, "<"&date+1)))))

    Acabei de adicionar algumas datas à planilha fornecida para poder testar se está funcionando. Usei CONT.SE para verificar o nome e o intervalo de datas de cada linha, e usei a função SE para evitar obter zero para linhas vazias, e MatrizFÓRMULA para todos os nomes ( A2:A13) de uma vez, e por último, a função POR COLUNA para obter coluna por coluna, para que você possa ter uma única fórmula que preencha a tabela inteira automaticamente.

    04/04/2025 05/04/2025 06/04/2025 07/04/2025
    Júlia 8 1 2 2
    Alex 2 1 1 1
    André 5 2 1 1
    Cinzas 4 1 1 1
    Erin 3 1 1 1
    John 4 1 1 3
    Josh 3 2 2 2
    Júlia 8 1 2 2
    Raio 5 1 2 1
    Sam 5 1 1 2
    Steve 2 1 1 2
    Trent 5 3 3 1
    • 0
  3. Best Answer

    Você também pode ter um resumo de dados mais estruturado usando o seguinte:

    Você pode selecionar o mês e/ou inserir o ano para filtrar os dados adequadamente:

    insira a descrição da imagem aqui

    =LET(
  data, 'Leads Data'!A2:B,
  m, MONTH(DATEVALUE(B1 & " 1")),
  y, VALUE(Q1),
  nm, INDEX(data,,2),
  dt, INDEX(data,,1),
  uniq, UNIQUE(nm),
  names, SORT(FILTER(uniq, uniq <> "")),
  cnt, MAKEARRAY(ROWS(names), 31,
        LAMBDA(r, c,
          COUNTIFS(nm, INDEX(names, r, 1),
                   dt, ">=" & DATE(y, m, c),
                   dt, "<" & DATE(y, m, c) + 1)
        )
      ),
  rs, BYROW(cnt, LAMBDA(row, SUM(row))),
  ct, BYCOL(cnt, LAMBDA(col, SUM(col)))
, VSTACK(
      HSTACK(names, cnt, rs),
      HSTACK(ROWS(names), ct, SUM(rs))
   )
)

    As formatações condicionais necessárias foram aplicadas para melhorar o resumo

    ATUALIZAR:

    OP: queria um Relatório Semanal com data de início (segunda-feira)

    insira a descrição da imagem aqui

    =LET(
  raw, UNIQUE(Sample!E2:E),
  names, SORT(FILTER(raw, raw<>"")),
  counts, MAKEARRAY(ROWS(names),7,LAMBDA(r,c,COUNTIFS(Sample!E2:E,INDEX(names,r),Sample!B2:B,">="&($D$1+c-1),Sample!B2:B,"<"&($D$1+c)))),
  rowTotals, BYROW(counts,LAMBDA(r,SUM(r))),
  dataBlock, HSTACK(names,counts,rowTotals),
  totals, HSTACK(ROWS(names),BYCOL(counts,LAMBDA(c,SUM(c))),SUM(rowTotals)),
  VSTACK(dataBlock,totals)
)
    • 0

relate perguntas