Início / coding / Perguntas / 79556561
Accepted
ezekiels
Asked: 2025-04-05 12:36:04 +0800 CST

Combinando Soma com Vlookup

  • 772

Tenho estes dados (tabela 1):

Column A
1999
5000
6666

E aqui está a tabela 2:

Col.C | Col.D (range)|  Col.E (margin)
1000  | 1000 - 1260  |  830
1261  | 1261 - 1261  |  0
1262  | 1262 - 1513  |  830
1514  | 1514 - 1514  |  0
1515  | 1515 - 2522  |  830
2523  | 2523 - 2523  |  0
2524  | 2524 - 5044  |  960
5045  | 5045 - 5045  |  0
5046  | 5046 - 5549  |  960
5550  | 5550 - 5550  |  0
5551  | 5551 - 6558  |  960
6559  | 6559 - 6559  |  0
6560  | 6560 - 6999  |  960

O valor na Coluna A tem um intervalo correspondente ( Coluna D ), ou seja: 1999 está no intervalo de 1515 a 2522. Portanto, a margem é 830. Minha pergunta é: como somar todas as margens da tabela 1?

Eu já tentei essas fórmulas:

formula1 =SUM(VLOOKUP(VLOOKUP(A:A;C:D;2);D:E;2;0)) 
formula2 =SUMIF(D:D;VLOOKUP(A:A;C:D;2);E:E)

Mas os resultados mostram apenas a margem da primeira linha, não a margem total

Result formula1 : 830
Result formula2 : 830

É mais fácil com a coluna auxiliar, e os resultados ficariam assim:

Col.A  | Margin
1999   | 830
5000   | 960
6666   | 960

O problema é que não quero usar nenhuma coluna auxiliar, já que meus dados têm 100.000 linhas por mês. As colunas auxiliares deixam meu Excel lento por causa da fórmula.

Só preciso saber a margem total (neste caso, o total é 2750). Existe alguma maneira de obter esse resultado sem a coluna auxiliar? Só consigo pensar em combinar SOMA/SOMASE e PROCV. Estou procurando há dias e encontrei muitos casos semelhantes neste fórum, mas sem sucesso.

Obrigado antecipadamente, qualquer ajuda é bem-vinda.

excel-formula

1 respostas

  1. Best Answer

    Todas as três fórmulas a seguir funcionaram para mim. Use qualquer uma das seguintes:

    =SUM(LOOKUP(Table1[Column A],Table2))

    =SUM(XLOOKUP(Table1[Column A],
 --TEXTBEFORE(Table2[Col.D (range)]," "),
 Table2[Col.E (margin)],,-1))

    =SUM(SUMIF(Table2[Col.D (range)],
 LOOKUP(Table1[Column A],Table2[[Col.C]:[Col.D (range)]]),
 Table2[Col.E (margin)]))

    E até mesmo a fórmula usada por também funcionou quando usada com a ajuda da TRIMRANGE()função ou de seus operadores de referência:

    =SUM(DROP(VLOOKUP(VLOOKUP(A.:.A,C.:.D,2,1),D.:.E,2,0),1))

    ou,

    =SUM(SUMIF(D.:.D,VLOOKUP(A.:.A,C.:.D,2,1),E.:.E))
    • 0

relate perguntas