Início / coding / Perguntas / 79555551
Accepted
DrTom
Asked: 2025-04-04 22:12:06 +0800 CST

Filtro indireto em tabela no Excel

  • 772

Tenho uma tabela como a mostrada na imagem a seguir.

Tabela Excel com subtotal na coluna Dados

Gostaria de ocultar a coluna Ano e permitir que o usuário selecione o ano do valor em A1 e filtre os resultados. O valor em B2 é um subtotal que mostra o valor mínimo para Dados com o filtro fornecido.

Isso é mesmo possível?

excel

1 respostas

  1. Best Answer

    Tabela de filtros excluindo coluna de filtros

    • Se você quis dizer filtragem no local, usar VBA é a única maneira.

    insira a descrição da imagem aqui

    MS365, Excel 2024

    =LET(table,Table1[#All],filter_column_title,"Year",filter_value,A1,
    ah,TAKE(table,1),
    fc,XMATCH(filter_column_title,ah),
    acs,SEQUENCE(,COLUMNS(table)),
    rcs,FILTER(acs,acs<>fc),
    rh,INDEX(ah,rcs),
    ad,DROP(table,1),
    fi,--IFERROR(INDEX(ad,,fc)=filter_value,),
    r,IF(SUM(fi)=0,rh,VSTACK(rh,FILTER(CHOOSECOLS(ad,rcs),fi))),
    r)
    • Ajuste as entradas na primeira linha, por exemplo, se os dados não estiverem em uma tabela estruturada, na barra de fórmulas selecione Table1[#All]e selecione o intervalo (incluindo cabeçalhos, por exemplo, A3:D13).
    • Substitua a variável mais abaixo rpor qualquer outra variável para ver o que ela contém.

    Passo a passo

    • Entradas

      table,Table1[#All],filter_column_title,"Year",filter_value,A1,

    • Todos os cabeçalhos (sem dados) [linha]

      ah,TAKE(table,1),

    • Índice da coluna do filtro [inteiro]

      fc,XMATCH(filter_column_title,ah),

    • Todos os índices de coluna [linha]

      acs,SEQUENCE(,COLUMNS(table)),

    • Índices de coluna resultantes [linha]

      rcs,FILTER(acs,acs<>fc),

    • Cabeçalhos resultantes (sem coluna de filtro) [linha]

      rh,INDEX(ah,rcs),

    • Todos os dados (sem cabeçalhos) [matriz]

      ad,DROP(table,1),

    • Filtro (1s e 0s) [coluna]

      fi,--IFERROR(INDEX(ad,,fc)=filter_value,),

    • Resultado (somente cabeçalhos se não houver correspondência) [linha]ou[matriz]

      r,IF(SUM(fi)=0,rh,VSTACK(rh,FILTER(CHOOSECOLS(ad,rcs),fi))),
    • 2

relate perguntas