Início / coding / Perguntas / 79552175
Accepted
Patryk Maryn
Asked: 2025-04-03 14:42:50 +0800 CST

KDB+ q - Qual é a lógica por trás dos valores retornados na função como lista

  • 772

Tenho uma função simples que é então definida como uma lista e invocada como uma lista:

f:{x*x}
q)(f; neg)[1; 2]
-2
q)(f; neg)[1; 3]
-3
q)(f; neg)[2; 3]
3
q)(f; neg)[4; 3]
3

para (f; neg)[1; 3] - ele retorna o mais à direita como neg (-3), mas então ele não retorna mais neg, pois o primeiro argumento se torna > 1, por exemplo: (f; neg)[2; 3] -> retorna 3

kdb+

2 respostas

  1. Esse comportamento é esperado. O que você está fazendo é indexar na lista de funções e então aplicar a função que foi retornada ao parâmetro que você passa como segundo parâmetro. Você pode ver isso aqui

    q)f
{x*x}
q)(f;neg)[0]
{x*x}
q)(f;neg)[1]
-:
q)neg
-:

    Basicamente o que acontece é que o primeiro parâmetro de [1;3] é o índice para sua lista de funções e o segundo parâmetro 3 é o valor que você está aplicando. Agora, por que isso não funciona para os dois últimos exemplos?
    Sempre que você indexa para uma lista com um índice que está fora do limite, ele retorna o elemento nulo correspondente do tipo de dados para essa lista.

    q)(1 2 3) 6
0N
q)(0101b) 6
0b

    O elemento nulo de uma lista de funções é a função identidade (::)que simplesmente retorna o parâmetro passado a ela como ele é

    q)(neg;min;max;avg)5
q)(neg;min;max;avg;::)4
q)(neg;min;max;avg;::)[4;5]
5
q)(::)5
5

    Espero que isso ajude. Você pode ler mais sobre a função de identidade aqui https://code.kx.com/q/ref/identity/
    E indexação aqui https://code.kx.com/q4m3/3_Lists/#34-indexing

    • 2
  2. Best Answer

    O primeiro argumento está sendo usado para indexar na lista de funções, e o segundo argumento é aplicado ao resultado:

    //case 1
(f; neg)[1; 2]

//find the 1st item in the list (which is -: aka neg)
q)((f;neg)[1])
-:

//apply the second input (2) to neg to get -2
q)((f;neg)[1])@2
-2

//case 2
(f; neg)[2; 2]

//find the second item in the list (it doesnt exist, returns identity function [see Alexander's answer])
q)(f;neg)[2]

//apply 2 to identity (just returns 2)
q)((f;neg)[2])@2
2
    • 2

relate perguntas