Início / coding / Perguntas / 79549469
Accepted
Lion King
Asked: 2025-04-02 09:23:34 +0800 CST

Como posso chamar a função printf corretamente a partir do assembly?

  • 772

Estou tentando chamar uma função C x86, printf, em assembly, mas há um erro de vinculação: error LNK2019: unresolved external symbol _printf referenced in function _main.

.model flat, C
.code
extern printf: proc

main proc
    push offset msg
    push offset fmt
    call printf
    ret
main endp

.data
    msg db "Hello world!", 0
    fmt db "%s", 0
end

Como posso resolver esse problema?

windows

3 respostas

  1. Best Answer

    pode haver várias maneiras. se quiser usar bibliotecas existentes - _printfestava dentro legacy_stdio_definitions.lib, mas se usá-lo, também precisa vincular legacy_stdio_wide_specifiers.libe ucrt.lib, chamar __initterm(ou definir o ponto de entrada para _wmainCRTStartup) o código completo neste caso pode parecer

    .686

.model flat

extern _printf: PROC
extern __imp__exit: DWORD
extern __imp___initterm: DWORD

.code

ep proc

    push offset __xc_z
    push offset __xc_a
    call __imp___initterm
    add esp,8
    
    push offset msg
    push offset fmt
    call _printf
    add esp,8
    
    push eax
    call __imp__exit
    
    ret
ep endp

CRT$XIA SEGMENT ALIAS(".CRT$XIA")
__xc_a DD 0
CRT$XIA ENDS

CRT$XIZ SEGMENT ALIAS(".CRT$XIZ")
__xc_z DD 0
CRT$XIZ ENDS

.const
    msg db "Hello world!", 0
    fmt db "%s", 0
end

    (observe que é melhor usar .consta seção .dataaqui para dados constantes)

    e linkar arquivo com

    
link.exe /MAP /MERGE:.CRT=.rdata /SUBSYSTEM:CONSOLE /ENTRY:ep /LARGEADDRESSAWARE /DYNAMICBASE /MACHINE:X86 /SAFESEH:NO /OPT:REF /OPT:ICF /NODEFAULTLIB /EMITPOGOPHASEINFO /EMITVOLATILEMETADATA:NO /LIBPATH:"C:\lib\um\x86" /LIBPATH:"C:\msvc\lib\x86" /LIBPATH:"C:\lib\ucrt\x86" test.obj legacy_stdio_definitions.lib legacy_stdio_wide_specifiers.lib ucrt.lib

    outra maneira - construa meu próprio msvcrt.lib (o msvcrt.lib padrão não tem, printfapesar de ter sido exportado por msvcrt.dlle então use-o) maneira mínima

    
.686
.model flat
API MACRO name
name proc
name endp
ENDM
.code
API _printf
end

    e msvcrt.def :

    EXPORTS
printf

    construir com

    link.exe /DLL /NOENTRY:ep /LARGEADDRESSAWARE /DYNAMICBASE /MACHINE:X86 /SAFESEH:NO /OPT:REF /OPT:ICF /NODEFAULTLIB /EMITPOGOPHASEINFO /EMITVOLATILEMETADATA:NO /DEF:msvcrt.def msvcrt.obj

    e então pode usar isso

    .686

.model flat

extern __imp__printf: DWORD
extern __imp__ExitProcess@4: DWORD

.code

ep proc

    push offset msg
    push offset fmt
    call __imp__printf
    add esp,8
    
    push eax
    call __imp__ExitProcess@4
    
    ret
ep endp

.const
    msg db "Hello world!", 0
    fmt db "%s", 0
end

    link com:

    link.exe /MAP /SUBSYSTEM:CONSOLE /ENTRY:ep /LARGEADDRESSAWARE /DYNAMICBASE /MACHINE:X86 /SAFESEH:NO /OPT:REF /OPT:ICF /NODEFAULTLIB /EMITPOGOPHASEINFO /EMITVOLATILEMETADATA:NO /LIBPATH:"C:\lib\um\x86" /LIBPATH:"C:\msvc\lib\x86" /LIBPATH:"C:\lib\ucrt\x86" test2.obj msvcrt.lib kernel32.lib

    (maneira mais geral de autoconstruir biblioteca para dll - aqui )

    • 1

  2. Exemplo de código de 32 bits:

            .686p                   ;enable instructions
        .xmm                    ;enable instructions
        .model flat,c           ;use C naming convention (stdcall is default)

;       include C libraries
        includelib      msvcrtd
        includelib      oldnames
        includelib      legacy_stdio_definitions.lib    ;for scanf, printf, ...

        .data                   ;initialized data
pfstr   db      "Hello world!",0dh,0ah,0
        .data?                  ;uinitialized data
        .stack  4096            ;stack (optional, linker will default)

        .code                   ;code 
        extrn   printf:near
        public  main

main    proc

        push    offset pfstr
        call    printf
        add     esp,4 

        xor     eax,eax
        ret
main    endp

        end

    Exemplo de código de 64 bits:

    ;       include C libraries
        includelib      msvcrtd
        includelib      oldnames
        includelib      legacy_stdio_definitions.lib    ;for scanf, printf, ...

        .data
msg     db      "test",00dh,00ah,000h
        .code
        extern  printf:near

main    proc
        sub     rsp,32                  ;caller allocates space for rcx,rcx,r8,r9
        lea     rcx,msg
        call    printf
        xor     eax,eax
        add     rsp,32
        ret
main    endp
        end
    • 0

  3. Se você estiver usando o Windows, a mainfunção deve ser nomeada_main

    • -1

relate perguntas