Início / coding / Perguntas / 79543876
Accepted
lalachka
Asked: 2025-03-30 04:40:35 +0800 CST

descobrir se o subformulário foi carregado de outro subformulário

  • 772

Tenho o código abaixo no subformulário1 de um formulário. Isso se refere ao subformulário2 não relacionado (fzzzSubConditionalFormatCriteria) no mesmo formulário.

ao abrir o formulário principal, recebo o erro ": Form : <Você inseriu uma expressão que tem uma referência inválida à propriedade Form/Report.> : Form", mas depois disso funciona bem quando clico nos registros. Como faço para contornar isso? ou, no pior cenário, simplesmente não execute este código ao abrir o formulário

Basicamente, é preciso uma maneira de saber quando um subformulário foi carregado e pode ser acessado

  vrSQL = "SELECT zzAppObjectFields.AppObjectField, zzAppObjectFields.AppObjectFieldTypeID, zzAppObjectFields.AppObjectIDCmb " & _
                            "FROM zzAppObjectFields WHERE zzAppObjectFields.AppObjectFieldTypeID In (10,12) AND zzAppObjectFields.AppObjectID=" & Me.AppObjectID & " " & _
                            "ORDER BY zzAppObjectFields.AppObjectField;"
    
                Me.Parent.fzzzSubConditionalFormatCriteria.Form!uuulllAppObjectFieldIDCriteria.RowSource = vrSQL
                Me.Parent.fzzzSubConditionalFormatCriteria.Form!uuulllAppObjectFieldIDCriteria.Requery
vba

1 respostas

  1. Best Answer

    Em resposta ao seu último comentário, você pode verificar o status de carregamento do seu subformulário com o seguinte código, que deve ser colocado em um módulo:

    Option Explicit

Public Function SubformNotLoaded(strFormName As String, _
                                 strSubFormName As String) As Boolean

  Dim frm As Access.Form

  On Error Resume Next

  ' Initialise return value.
  SubformNotLoaded = False

  ' Attempt to reference the subform
  Set frm = Forms(strFormName).Controls(strSubFormName).Form

  ' An error is thrown if the subform has not yet been fully loaded.
  If Err.Number <> 0 Then
    ' Set the return value.
    SubformNotLoaded = True
  End If

  ' Housekeeping.
  Err.Number = 0
  Set frm = Nothing

End Function

    Você pode então chamar essa função de qualquer lugar no seu código da seguinte maneira, simplesmente passando o nome do formulário que contém o subformulário e também o nome do próprio subformulário:

      If SubformNotLoaded("frmForm", "frmSubForm2") = True Then
    MsgBox "Subform not fully loaded."
  Else
    MsgBox "Subform is fully loaded."
  End If
    • 2

relate perguntas