Início / coding / Perguntas / 79543129
Accepted
GuidoG
Asked: 2025-03-29 18:56:12 +0800 CST

Como fazer hash de uma string Delphi usando SHA256 para corresponder a um hash de C#?

  • 772

Em C#, temos esta função:

public string GetStringSha256Hash(string text, Encoding coding)
{
    string result = "";
    if (text != null)
    {
        using (SHA256 sHA256Managed = SHA256.Create())
        {
            byte[] bytes = coding.GetBytes(text);
            byte[] array = sHA256Managed.ComputeHash(bytes);
            result = BitConverter.ToString(array).Replace("-", string.Empty);
        }
    }
     return result;
}

Estou tentando fazer o mesmo no Delphi, mas continuo obtendo resultados diferentes.

Algo tão simples como isto:

Result := THashSHA2.GetHashString(Text);

retorna um resultado diferente.

Suspeito que seja porque em C# sempre usamos UTF-8, mas não consigo descobrir como usar codificação em Delphi.

Eu tentei isso:

var
  Hash: TIdHashSHA256;
begin
  Hash := TIdHashSHA256.Create;

  try
    SHA256Hash := Hash.HashString(Text, TEncoding.UTF8);

mas dá erro de compilação

[Erro dcc32] Unit1.pas(216): E2010 Tipos incompatíveis: 'IIdTextEncoding' e 'TEncoding'

Qual é a maneira correta de fazer isso no Delphi?

O valor 12345retorna 1445217533E7D4D0CFFD9109C4EDB60D62A02C0F0DE9537BE44F5E00D348EB4Fem C#, mas 5994471abb01112afcc18159f6cc74b4f511b99806da59b3caf5a9c173cacfc5em Delphi.

Quero que a versão Delphi retorne o mesmo valor que a versão C#.

delphi

1 respostas

  1. Best Answer

    Hashes são calculados em bytes, não em caracteres de texto. Qualquer código que você usar para fazer hash de uma string precisará codificar os caracteres em bytes antes de calcular o hash nos bytes. Ao fazer hash de strings em sistemas diferentes, você precisa ter certeza de que elas estão usando a mesma codificação de bytes.

    O código C# está codificando a entrada stringpara um array de bytes via coding.GetBytes(text). Você não indicou qual Encodingestá sendo passado para GetStringSha256Hash(), mas o resultado do hash C# que você mostrou é o que você obtém ao fazer o hash de uma string usando UTF-16LE (ou seja, Encoding.Unicode).

    Ao usar a classe Delphi RTL THashSHA2, ela não permite que você especifique uma codificação de bytes ao fazer hash de um string. O GetHashString()método que recebe a stringé codificado para usar TEncoding.UTF8. Isso é consistente com o resultado do hash Delphi que você mostrou. Para usar uma codificação de bytes diferente, as opções alternativas são:

    • use a THashSHA2.GetHashString()sobrecarga que recebe um TStream, e então você pode passar um fluxo contendo bytes codificados em UTF-16LE, por exemplo:

      function GetStringSha256Hash(const Text: string; Encoding: TEncoding): string;
begin
  Result := '';
  if Text <> '' then
  begin
    var Stream := TStringStream.Create(Text, Encoding);
    try
      Result := THashSHA2.GetHashString(Stream);
    finally
      Stream.Free;
    end;
  end;
end;

      var SHA256Hash := GetStringSha256Hash('1235', TEncoding.Unicode);

    • use o THashSHA2.Update()método, passando-lhe uma matriz de bytes codificada em UTF-16, por exemplo:

      function GetStringSha256Hash(const Text: string; Encoding: TEncoding): string;
begin
  Result := '';
  if Text <> '' then
  begin
    var Hash := THashSHA2.Create(TSHA2Version.SHA256);
    Hash.Update(Encoding.GetBytes(Text));
    Result := Hash.HashAsString;
  end;
end;

      var SHA256Hash := GetStringSha256Hash('1235', TEncoding.Unicode);

    Ao usar a classe do Indy TIdHashSHA256, o erro do compilador é causado pelo fato de que o Indy não usa a TEncodingclasse 1 do Delphi RTL , mas sim sua própria IIdTextEncodinginterface (porque o Indy ainda suporta versões pré-Unicode do Delphi que não têm a SysUtils.TEncodingclasse disponível), por exemplo:

    function GetStringSha256Hash(const Text: string; const Encoding: IIdTextEncoding): string;
begin
  Result := '';
  if Text <> '' then
  begin
    var Hash := TIdHashSHA256.Create;
    try
      Result := Hash.HashString(Text, Encoding);
    finally
      Hash.Free;
    end;
  end;
end;

    var SHA256Hash := GetStringSha256Hash('1235', IndyTextEncoding_UTF16LE);

    1 : Se você quiser usar um SysUtils.TEncodingcom Indy, você pode envolvê-lo em um IIdTextEncodingusando a IndyTextEncoding()função na IdGlobalunidade, por exemplo:

    function GetStringSha256Hash(const Text: string; Encoding: TEncoding): string;
begin
  Result := '';
  if Text <> '' then
  begin
    var Hash := TIdHashSHA256.Create;
    try
      Result := Hash.HashString(Text, IndyTextEncoding(Encoding));
    finally
      Hash.Free;
    end;
  end;
end;

    var SHA256Hash := GetStringSha256Hash('1235', Encoding.Unicode);
    • 14

relate perguntas