Início / coding / Perguntas / 79429840
Accepted
Abdullah
Asked: 2025-02-11 19:38:10 +0800 CST

Como posso evitar registros duplicados ao inserir em uma tabela Oracle?

  • 772

Tenho um aplicativo Apex e obtive duplicatas ao inserir,

Como posso evitar linhas duplicadas

Este é o código:

DECLARE
      CURSOR p1 IS
        SELECT DISTINCT 
            sd.TEST_NO,
            b.TEST_NAME_ENG,
            a.PATIENT_NO,
            a.ORDER_ID,
            sd.SAMPLE_ID,
            a.SECTION_ID,
            b.SAMPLE_TYPE,
            b.TEST_CONTAINER,
            b.TEST_VOLUME,
            a.SAMPLE_STATUS,
            a.CUST_NO,
            DECODE(o.ORDER_PRIORITY, 1, 'URGENT', 2, 'ROUTINE') AS ORDER_PRIORITY , 
            p.TEST_NAME,p.REFERENCE_RANGE, p.TEST_UNIT , p.SERIAL
        FROM 
            LAB_SAMPLE_HEADER a,
            LAB_TESTS b,
            LAB_SAMPLE_DETAILS sd,
            LAB_ORDERS o , 
            LAB_TEMPLATE_DETAILS p 

        WHERE 
            sd.TEST_NO = b.TEST_NO
            AND a.ORDER_ID = o.ORDER_ID
            AND sd.ORDER_ID = o.ORDER_ID
            AND a.ORDER_ID = sd.ORDER_ID
            AND a.SAMPLE_ID = sd.SAMPLE_ID
            AND a.PATIENT_NO = :P60_MRN 
            AND sd.TEST_NO = p.TEST_NO 
            AND a.order_id = :P60_ORDER
            AND B.TEST_NO IN (
                SELECT REGEXP_SUBSTR(:P60_TEST_NO, '[^,]+', 1, LEVEL) AS TESTNO
                FROM DUAL
                CONNECT BY LEVEL <= REGEXP_COUNT(:P60_TEST_NO, ',') + 1
            );


    CURSOR para_tests(p_test_no IN NUMBER) IS
    select TEST_NO,TEST_NAME,REFERENCE_RANGE, TEST_UNIT , SERIAL
    from LAB_TEMPLATE_DETAILS para 
    where para.test_no = p_test_no;
  
   v_profile_exists number; -- Variable to check if the TEST_NO belongs to a profile
   v_para_exists number; -- Variable to check if the TEST_NO belongs to a parasitology
BEGIN
    
    FOR i IN p1 LOOP
             -- Check if the current TEST_NO is part of a template
        SELECT COUNT(*) INTO v_para_exists
        FROM LAB_TEMPLATE_DETAILS
        WHERE test_no = i.TEST_NO;
        
        IF v_para_exists > 0 THEN
            -- TEST_NO is part of a parasitology, insert only parasitology tests
            FOR p IN para_tests(i.TEST_NO) LOOP
                INSERT INTO LAB_PARA_RESULTS
                (
                    ORDER_ID, SAMPLE_ID, PATIENT_NO, TEST_NO, TEST_NAME, TEST_RESULT , REFERENCE_RANGE , 
                    TEST_UNIT , SERIAL , EXAMINED_BY, EXAMINED_DATE, APPROVED_BY, APPROVED_DATE, CUST_NO , SAMPLE_STATUS ) 
                    VALUES (
                    i.ORDER_ID, -- ORDER_ID from cursor
                    i.SAMPLE_ID, -- SAMPLE_ID from cursor
                    i.PATIENT_NO, -- PATIENT_NO from cursor
                    p.TEST_NO, -- TEST_NO from para 
                    i.TEST_NAME ,
                    NULL , 
                    i.REFERENCE_RANGE , 
                    i.TEST_UNIT , 
                    i.SERIAL , -- SERIAL
                    NULL , -- EXAMINED_BY
                    NULL, -- EXAMINED_DATE
                    NULL, -- APPROVED_BY
                    NULL , -- APPROVED_DATE 
                    i.CUST_NO, -- CUST_NO from cursor
                    3 -- SAMPLE_STATUS
                                       
                );
            END LOOP;
            end if;
         END LOOP;
         
    COMMIT; -- Commit the transaction
END;

o cursor p1 retorna o número correto de linhas sem duplicatas

o cursor para_tests também retorna o número correto sem duplicatas

mas ao inserir linhas ele é duplicado

por exemplo, o cursor p1 retorna 10 linhas, mas ao inserir, cada linha é duplicada 10 vezes, com um total de 100 linhas.

Como evitar duplicatas no loop ao INSERT INTO LAB_PARA_RESULTS?

plsql

1 respostas

  1. Best Answer

    Você não forneceu nenhum dado de amostra, então é impossível testar, mas, em geral, você pode (e deve) evitar cursores e loops e fazer tudo em uma única consulta, se possível:

    BEGIN
  INSERT INTO LAB_PARA_RESULTS (
    ORDER_ID,
    SAMPLE_ID,
    PATIENT_NO,
    TEST_NO,
    TEST_NAME,
    TEST_RESULT,
    REFERENCE_RANGE, 
    TEST_UNIT,
    SERIAL,
    EXAMINED_BY,
    EXAMINED_DATE,
    APPROVED_BY,
    APPROVED_DATE,
    CUST_NO,
    SAMPLE_STATUS
  )
  SELECT DISTINCT 
         a.ORDER_ID,
         sd.SAMPLE_ID,
         a.PATIENT_NO,
         sd.TEST_NO,
         p.TEST_NAME,
         NULL, -- REFERENCE RANGE
         p.REFERENCE_RANGE,
         p.TEST_UNIT,
         p.SERIAL,
         NULL, -- EXAMINED_BY
         NULL, -- EXAMINED_DATE
         NULL, -- APPROVED_BY
         NULL, -- APPROVED_DATE 
         a.CUST_NO,
         3 -- SAMPLE_STATUS
  FROM   LAB_TESTS b
         INNER JOIN LAB_SAMPLE_DETAILS sd
         ON sd.TEST_NO = b.TEST_NO
         INNER JOIN LAB_ORDERS o
         ON sd.ORDER_ID = o.ORDER_ID
         INNER JOIN LAB_SAMPLE_HEADER a
         ON a.ORDER_ID = o.ORDER_ID
            AND a.SAMPLE_ID = sd.SAMPLE_ID
         INNER JOIN LAB_TEMPLATE_DETAILS p 
         ON sd.TEST_NO = p.TEST_NO
  WHERE  a.PATIENT_NO = :P60_MRN 
  AND    a.order_id = :P60_ORDER
  AND    ',' || :P60_TEST_NO || ',' LIKE '%,' || B.TEST_NO || ',%';

  COMMIT;
END;

    Observação:

    • Sua COUNTverificação é realizada implicitamente pela junção, LAB_TEMPLATE_DETAILS pentão você não precisa duplicá-la explicitamente.
    • Sua consulta já executa o equivalente a CURSOR para_testsunir LAB_TEMPLATE_DETAILS p, então fazê-lo em um segundo cursor (aninhado) é redundante (e provavelmente é a causa do seu problema).
    • 2

relate perguntas