Início / coding / Perguntas / 79427096
Accepted
Renaud Pacalet
Asked: 2025-02-10 20:37:57 +0800 CST

Como verificar se uma variável existe e atribuir a ela um valor padrão caso não exista?

  • 772

Com o GNU awk5.3.1, quero atribuir um valor padrão a uma variável se ela não tiver recebido um na linha de comando. O valor pode ser qualquer coisa, incluindo 0. Pensei que poderia usar, SYMTABmas como SYMTABé construído durante a análise e antes da execução, não funciona:

$ awk -v v=1 'BEGIN { if(!("v" in SYMTAB)) v = 42; print "v = " v }' /dev/null
v = 1
$ awk 'BEGIN { if(!("v" in SYMTAB)) v = 42; print "v = " v }' /dev/null
v =

Existe outra maneira?

awk

2 respostas

  1. Eu exploraria typeofa função para esta tarefa da seguinte maneira

    awk -v v=1 'BEGIN{print typeof(v)=="untyped"?"v was not given":"v was given"}' /dev/null
awk 'BEGIN{print typeof(v)=="untyped"?"v was not given":"v was given"}' /dev/null

    dá saída

    v was given
v was not given

    (testado no GNU Awk 5.3.1)

    • 3
  2. Best Answer

    A maneira de determinar se uma variável está definida ou não em qualquer awk é comparando-a com ambos 0e , nullcomo o valor inicial para qualquer variável escalar é 0-or-null, não há necessidade de uma SYMTAB[]pesquisa específica do gawk (que você já descobriu que não pode usar para isso, pois a variável vexistirá em , SYMTAB[]pois é mencionada no seu código) ou typeof()chamada. Por exemplo:

    $ awk -v v=1 'BEGIN { if((v=="") && (v==0)) v = 42; print "v = " v }'
v = 1

$ awk -v v=0 'BEGIN { if((v=="") && (v==0)) v = 42; print "v = " v }'
v = 0

$ awk -v v= 'BEGIN { if((v=="") && (v==0)) v = 42; print "v = " v }'
v =

$ awk 'BEGIN { if((v=="") && (v==0)) v = 42; print "v = " v }'
v = 42

    A propósito, é assim que você também pode saber se um parâmetro opcional para uma função foi passado ou não.

    A propósito, além da portabilidade, há uma diferença funcional entre a abordagem acima e o uso do gawk, typeof(v) == "untyped"conforme sugerido em outro lugar:

    $ awk 'BEGIN { print "v = " v; if((v=="") && (v==0)) v = 42; print "v = " v }' /dev/null
v =
v = 42

$ awk 'BEGIN { print "v = " v; if(typeof(v) == "untyped") v = 42; print "v = " v }' /dev/null
v =
v =

    Se você for usar typeof()isso, precisará verificar se a saída é untypedou unassigned:

    $ awk 'BEGIN { print "v = " v; if(typeof(v) ~ /^un(typed|assigned)$/) v = 42; print "v = " v }' /dev/null
v =
v = 42

    Veja a página de manual do gawk para mais informações sobre isso :-).

    • 2

relate perguntas