Início / coding / Perguntas / 79426134
Accepted
Rasec Malkic
Asked: 2025-02-10 13:25:30 +0800 CST

Extrair linhas após a string e imprimir vários valores em uma única linha

  • 772

Tenho vários arquivos com um formato como este

some text
some text
This section is for WXYZ
some text
some text
some text
some text
some text
some text (ABC) some text (CDF)
901 98
some text FFG
some text (FFG)
1 99
some text
some text

Estou tentando imprimir para cada arquivo

  1. o nome do arquivo
  2. a string após "Esta seção é para" na mesma linha
  3. a linha abaixo da string contendo(ABC)
  4. a linha abaixo da string contendo(FFG)

Este é meu script atual (com base na resposta neste tópico )

awk '/This section is for/{sub(/This section is for /,""); print FILENAME "|" $0}
     a{print;a=0} /\(ABC\)/{a=1}
     b{print;b=0} /\(FFG\)/{b=1}
' "testfile.txt"

Estou obtendo esta saída

testfile.txt|WXYZ
901 98
1 99

E minha saída desejada para cada arquivo seria uma única linha como esta

testfile.txt|WXYZ|901 98|1 99

Como modificar o script para obter meu objetivo? Obrigado

awk

3 respostas

  1. Best Answer

    Assim, usando printf "%s"para evitar quebras de linha:

    $ awk '/This section is for/{sub(/This section is for /,""); printf "%s", FILENAME "|" $0}
     a{printf "|%s", $0;a=0} /\(ABC\)/{a=1}
     b{printf "|%s\n", $0;b=0} /\(FFG\)/{b=1}
' testfile.txt
testfile.txt|WXYZ|901 98|1 99
    • 1

  2. Sempre que tenho uma entrada que contém pares de tag-valor, acho útil primeiro construir uma matriz desses mapeamentos ( f[]abaixo) para separar a detecção do valor do uso do valor e, então, posso imprimir, comparar e modificar em qualquer ordem e combinação que eu quiser, apenas indexando a matriz com sua tag (nome).

    Por exemplo, usando qualquer awk:

    awk -v OFS='|' '
    /^This section is for/ { f["sect"] = $NF }
    tag != "" { f[tag] = $0; tag = "" }
    match($0, /\([^()]+)/) { tag = substr($0,RSTART+1,RLENGTH-2) }
    END { print FILENAME, f["sect"], f["ABC"], f["FFG"] }
' "testfile.txt"
testfile.txt|WXYZ|901 98|1 99

    Observe que isso forneceria consistentemente 4 |campos de saída separados, mesmo se alguma das tags estivesse faltando em um arquivo de entrada.

    Já que você disse:

    Tenho vários arquivos...

    se você quisesse processar todos os arquivos de entrada de uma vez, você poderia fazer isso com o GNU awk:

    awk -v OFS='|' '
    /^This section is for/ { f["sect"] = $NF }
    tag != "" { f[tag] = $0; tag = "" }
    match($0, /\(([^()]+))/, a) { tag = a[1] }
    ENDFILE {
        print FILENAME, f["sect"], f["ABC"], f["FFG"]
        delete f
    }
' *.txt

    ou isso com qualquer awk:

    awk -v OFS='|' '
    FNR == 1 { prt() }
    /^This section is for/ { f["sect"] = $NF }
    tag != "" { f[tag] = $0; tag = "" }
    match($0, /\([^()]+)/) { tag = substr($0,RSTART+1,RLENGTH-2) }
    END { prt() }

    function prt() {
        if ( prevFname != "" ) {
            print prevFname, f["sect"], f["ABC"], f["FFG"]
            delete f
        }
        prevFname = FILENAME
    }
' *.txt
    • 0

  3. O GNU AWKadiciona um separador de linha de saída ao conteúdo de print, que por padrão é uma nova linha ( \n), você pode alterá-lo definindo outro ORSvalor, neste caso específico, deixe testfile.txto conteúdo ser

    some text
some text
This section is for WXYZ
some text
some text
some text
some text
some text
some text (ABC) some text (CDF)
901 98
some text FFG
some text (FFG)
1 99
some text
some text

    então

    awk 'BEGIN{ORS="|"}/This section is for/{sub(/This section is for /,""); print FILENAME "|" $0}
     a{print;a=0} /\(ABC\)/{a=1}
     b{print;b=0} /\(FFG\)/{b=1}
' "testfile.txt"

    vai dar

    testfile.txt|WXYZ|901 98|1 99|

    Observe que há uma quebra |de linha no final, isso pode ser corrigido da seguinte maneira

    awk 'BEGIN{ORS="|"}/This section is for/{sub(/This section is for /,""); print FILENAME "|" $0}
     a{print;a=0;ORS="\n"} /\(ABC\)/{a=1}
     b{print;b=0;ORS="\n"} /\(FFG\)/{b=1}
' "testfile.txt"

    que dá saída

    testfile.txt|WXYZ|901 98|1 99

    Explicação: Eu mudo ORSpara nova linha após printing a primeira de duas linhas, independentemente de quais linhas ( aou b) vêm primeiro. Se você quiser saber mais sobre ORS, leia 8 Variáveis ​​Internas Poderosas do Awk – FS, OFS, RS, ORS, NR, NF, FILENAME, FNR

    (testado no GNU Awk 5.3.1)

    • 0

relate perguntas