Como tornar uma imagem 60% transparente no VBA?

Tenho que admitir que foi muito mais desafiador do que eu pensava que seria (ou então eu poderia ter complicado demais):

Sub InsertRectangleWithImage()
    Dim ws As Worksheet
    Dim shp As Shape
    Dim imgURL As String
    Dim imgPath As String
    
    Set ws = ThisWorkbook.Sheets("Sheet1")

    imgURL = "https://cdn.hubblecontent.osi.office.net/m365content/publish/0b4f7be0-2a71-43c6-a762-bba962e256c3/182654618.jpg"

    imgPath = Environ("TEMP") & "\tempImage.jpg"
    DownloadFile imgURL, imgPath

    Set shp = ws.Shapes.AddShape(msoShapeRectangle, 50, 50, 200, 100)

    shp.Fill.UserPicture imgPath
    
    shp.Fill.Transparency = 0.4

    Kill imgPath
End Sub


Private Sub DownloadFile(URL As String, LocalFilePath As String)
    Dim WinHttpReq As Object
    Set WinHttpReq = CreateObject("WinHttp.WinHttpRequest.5.1")
    WinHttpReq.Open "GET", URL, False
    WinHttpReq.Send

    If WinHttpReq.Status = 200 Then
        Dim adoStream As Object
        Set adoStream = CreateObject("ADODB.Stream")
        adoStream.Open
        adoStream.Type = 1 ' Binary
        adoStream.Write WinHttpReq.ResponseBody
        adoStream.Position = 0 ' Set the stream position to the start
        adoStream.SaveToFile LocalFilePath, 2 ' Overwrite if file exists
        adoStream.Close
    End If
End Sub

Faça referência à forma e sua Fill.Transparencypropriedade.

Public Sub Test()

    ChangeTransparency "Picture 3", 0.6
    ChangeTransparency "Rectangle 4", 0.3
    ChangeTransparency "Graphic 6", 0.8

End Sub

Public Sub ChangeTransparency(ShapeName As String, TransparencyPercent As Double)

    Dim MyShape As Shape
    
    Set MyShape = ThisWorkbook.Worksheets("Sheet1").Shapes(ShapeName)
    MyShape.Fill.Transparency = TransparencyPercent

End Sub  

Como uma única linha:

ThisWorkbook.Worksheets("Sheet1").Shapes("Rectangle 4").Fill.Transparency = 0.3

Editar:
Tendo olhado seu segundo link, acho que você está atrás de tornar uma imagem transparente em vez do fundo da imagem, o que você provavelmente descobriu que o código não faz se você usar inserir imagem.
Em vez disso, insira um retângulo e defina seu preenchimento como uma Imagem ou preenchimento de textura .