Início / coding / Perguntas / 79343798
Accepted
Forward Ed
Asked: 2025-01-10 03:20:12 +0800 CST

Prática recomendada para verificar se uma entrada de célula gerará um erro

  • 772

Situação:

Estou usando o conteúdo da célula "D2" para nomear a planilha. Acabei de editar o código abaixo para capturar várias entradas problemáticas, postar uma mensagem e fornecer um valor que funciona e é óbvio que precisa ser substituído.

Código:

Private Sub Worksheet_Change(ByVal Target As Range)
    
    Dim BadData As Boolean
    
    If Intersect(Target, ThisWorkbook.Sheets(2).Range("D2")) Is Nothing Then
        Exit Sub
    End If
    
   BadData = False
        
    If Len(Target.Value) > 31 Or IsEmpty(Target.Value) Then
        BadData = True
    ElseIf InStr(Target.Value, "[") <> 0 Then
        BadData = True
    ElseIf InStr(Target.Value, "]") <> 0 Then
        BadData = True
    ElseIf InStr(Target.Value, "*") <> 0 Then
        BadData = True
    ElseIf InStr(Target.Value, "?") <> 0 Then
        BadData = True
    ElseIf InStr(Target.Value, "\") <> 0 Then
        BadData = True
    ElseIf InStr(Target.Value, "/") <> 0 Then
        BadData = True
    ElseIf InStr(Target.Value, ":") <> 0 Then
        BadData = True
    End If
    
    If BadData Then
        MsgBox "You have entered an unacceptable ID value." & vbCrLf & _
                vbCrLf & _
                "The Site No entry must:" & vbCrLf & _
                vbCrLf & _
                "1)  Be a value less than 31 characters long" & vbCrLf & _
                "2)  Not contain the following characters:  /, \, :, ?, *, [, ]" & vbCrLf & _
                "3)  Not be a blank value" & vbCrLf & _
                "4)  Be compatible with excel sheet name restrictions"
                
        Target.Value = "Enter Site ID"
    End If
    
    ThisWorkbook.Sheets(2).Name = Target.Value

End Sub

Embora o código acima pareça funcionar, tenho certeza de que há várias outras maneiras de atingir o mesmo resultado final. A declaração IF múltipla resultando no mesmo valor me incomodou um pouco.

Originalmente, pensei em colocar todas as verificações individuais de InStr em uma declaração OR longa com as verificações Len e IS Empty, mas escolhi não fazer isso, pois imaginei que seria um problema para outra pessoa tentar descobrir o código. Percebi que pode haver algum benefício em ELSEIF impedir que verificações subsequentes sejam feitas se uma verificação TRUE resultar.

Pergunta

Eu queria saber se existe uma maneira melhor de fazer isso?

excel

1 respostas

  1. Best Answer

    Você pode colocá-lo em uma função e então usá-la? Dessa forma, você pode manter (adicionar, remover condições) a função.

    '~~> UNTESTED
Private Function IsBadData(CellValue As Variant) As Boolean
    Dim BadString As String
    Dim BadData As Boolean
    Dim MyAr
    Dim i As Long
    
    BadString = "[,],*,?,\,/,:"
    
    If Len(Trim(CellValue)) = 0 or Len(Trim(CellValue)) > 31 Then
        BadData = True
    Else
        MyAr = Split(BadString, ",")
    
        For i = LBound(MyAr) To UBound(MyAr)
            If InStr(1, CellValue, MyAr(i)) Then
                BadData = True
                Exit For
            End If
        Next i
    End If
    
    IsBadData = BadData
End Function

    Uso :

    If IsBadData(Target.Value) Then
    MsgBox "Blah Blah"
End If
    • 3

relate perguntas