主页 / coding / 问题 / 79211030
Accepted
Srikanth
Asked: 2024-11-21 19:54:14 +0800 CST

文本总和不包含在范围内

  • 772

你好，我有超过 15K 行的数据。

我想对列表中的项目求和，并计算不在列表中的项目的总和。

当它包含在范围内时，我会使用 textsplit 函数获得结果。下面是我的公式：

=SUM(--(TEXTSPLIT(F2,",")=B2:B12)*C2:C12)

如果我对“不等于”使用相同的公式，则不会给出准确的结果。我卡在这里，可能是什么原因。

=SUM(--(TEXTSPLIT(F2,",")<>B2:B12)*C2:C12)

但不知何故我使用过滤功能来管理我的工作。

=SUM(FILTER(C2:C12,(B2:B12<>"A")*(B2:B12<>"D")*(B2:B12<>"E")*(B2:B12<>"H")*(B2:B12<>"K")))

有人能帮我解释一下为什么当我使用“不等于”时 Textsplit 函数没有给出准确的结果

谢谢 ：-）

图片

excel

3 个回答

  1. 正确答案应该是13，不是10，除非我遗漏了什么。

    你可以分解你的公式来了解为什么你会得到这样的结果128。

    当将水平向量与垂直向量相乘时，结果是一个矩阵。

    =TEXTSPLIT(F5,",")<>B2:B12

    结果：
    在此处输入图片描述

    将该矩阵乘以 C 列，可获得：
    在此处输入图片描述

    所有这些数字的总和是 128。

    一种方法TEXTSPLIT是分别处理每一行。

    =SUM(BYROW(TEXTSPLIT(F5,",")<>B2:B12,LAMBDA(ARR,AND(ARR)))*C2:C12)

    答案是13

    • 2
  2. Best Answer

    另一种替代方法是，当它不等于 A、D、E、H、K 的分割值时，应该是10这样的13

    在此处输入图片描述

    =LET(
 a, TEXTSPLIT(E2,","),
 SUM(FILTER(C$2:C$12,MMULT(N(a=B$2:B$12),SEQUENCE(COLUMNS(a))^0)=0)))

    为了得到等于的逆：

    =LET(
 a, TEXTSPLIT(E2,","),
 SUM(FILTER(C$2:C$12,MMULT(N(a=B$2:B$12),SEQUENCE(COLUMNS(a),,,0))>0)))

    根据 OP：

    谢谢@Mayukh，只需考虑 A=1、B=1、C=1....K=1。A、D、E、H、K 包括结果 5，而 B、C、F、G、I、J 不包括结果 6。我希望 这会给出明确的结果。– Srikanth

    给定的公式正常工作，请尝试在您的终端进行测试，以下屏幕截图表明：

    在此处输入图片描述

    我们可以排除该FILTER()函数：

    =LET(
     a,TEXTSPLIT(E2,","),
     SUM((MMULT(N(a=B$2:B$12),SEQUENCE(COLUMNS(a),,,0))>0)*C$2:C$12))

    和

    =LET(
     a,TEXTSPLIT(E2,","),
     SUM((MMULT(N(a=B$2:B$12),SEQUENCE(COLUMNS(a),,,0))=0)*C$2:C$12))
    • 1

  3. 一个非常简单的公式

    [E2]=SUM($C$2:$C$12*ISERROR(FIND($B$2:$B$12,D2)))

    填满。

    在此处输入图片描述

    • 0

相关问题