如何通过 Excel 公式获取两个集合的笛卡尔积

一个通用的选择可能是：

=CROSSJOIN(Table1,Table2)

CROSSJOIN名称管理器中定义的自定义函数在哪里：

=LAMBDA(array1,array2,
    LET(
        i, SEQUENCE(ROWS(array1)),
        j, SEQUENCE(, ROWS(array2)),
        HSTACK(
            CHOOSEROWS(array1, TOCOL(IF(j, i))),
            CHOOSEROWS(array2, TOCOL(IF(i, j)))
        )
    )
)

来源：https ://stackoverflow.com/a/78244826/22459970

如果您还想要处理标题行的选项，CROSSJOIN可以定义如下：

=LAMBDA(array1,array2,[headers],
    LET(
        incl_h, CHOOSE(headers + 1, 0, 1, 0, 1),
        show_h, CHOOSE(headers + 1, 0, 0, 1, 1),
        a, DROP(array1, incl_h),
        b, DROP(array2, incl_h),
        i, SEQUENCE(ROWS(a)),
        j, SEQUENCE(, ROWS(b)),
        v, HSTACK(
            CHOOSEROWS(a, TOCOL(IF(j, i))),
            CHOOSEROWS(b, TOCOL(IF(i, j)))
        ),
        IF(
            show_h,
            VSTACK(
                IF(
                    incl_h,
                    HSTACK(
                        TAKE(array1, 1),
                        TAKE(array2, 1)
                    ),
                    HSTACK(
                        "tbl1.Col" & SEQUENCE(, COLUMNS(a)),
                        "tbl2.Col" & SEQUENCE(, COLUMNS(b))
                    )
                ),
                v
            ),
            v
        )
    )
)

可选的[headers]参数的行为方式与 的[field_headers]参数类似GROUPBY，其中接受以下选项：

• 0 | 没有
• 1 | 是，但不显示
• 2 | 否，但生成
• 3 | 是并展示

例如：

=CROSSJOIN(Table1,Table2,2)

或者：

=CROSSJOIN(Table1[#All],Table2[#All],3)

请注意，换行符和空格/缩进是为了提高可读性而使用的。在名称管理器中定义函数时可以删除它们。

有一个基于的解决方案MAKEARRAY：

=MAKEARRAY(
  ROWS(Set_1)*ROWS(Set_2),
  COLUMNS(Set_1)+COLUMNS(Set_2),
  LAMBDA(row,col,
         LET(set_num,IF(col<=COLUMNS(Set_1),1,2),CHOOSE(set_num,
            INDEX(Set_1,QUOTIENT(row-1,3)+1,col),
            INDEX(Set_2,MOD(row-1,3)+1,col-COLUMNS(Set_1))))))

不使用LAMBDA()辅助函数：

=LET(
     a, TOROW(DataTwo[Column1]&"|"&DataTwo[Column2]),
     b, TOCOL(DataOne[Column1]&"|"&DataOne[Column2]&"|"&a),
     TEXTSPLIT(TEXTAFTER("|"&b,"|",SEQUENCE(,4)),"|"))

• 或者，选项二：

=LET(
     a, ROWS(DataTwo),
     b, ROWS(DataOne),
     c, CHOOSEROWS(DataOne,INT((SEQUENCE(a*b)-1)/a)+1),
     d, CHOOSEROWS(DataTwo,MOD((SEQUENCE(a*b)-1),a)+1),
     HSTACK(c,d))

最后改变变量来评估：

=LET(
     a, ROWS(DataTwo),
     b, ROWS(DataOne),
     c, SEQUENCE(a*b),
     d, CHOOSEROWS(DataOne,INT((c-1)/a)+1),
     e, CHOOSEROWS(DataTwo,MOD((c-1),a)+1),
     f, HSTACK(d,e),
     f)

笛卡尔积

=LET(data1,Table11,data2,Table12,
    Repeat,LAMBDA(fs,ss,by_col,
        TOCOL(IF(TOROW(ss),fs),,by_col)),
    fs,SEQUENCE(ROWS(data1)),
    ss,SEQUENCE(ROWS(data2)),
    HSTACK(CHOOSEROWS(data1,Repeat(fs,ss,0)),
        CHOOSEROWS(data2,Repeat(ss,fs,1))))

TOCOL/IF/序列

效率

• 我从未遇到过此组合比INT/MOD组合更高效的情况。不是在使用它们本身时（没有明显的区别），而是与其他功能结合使用时。
• 在这个特定案例中，在两张 1000 行 5 列的表格中，此组合花费了 10 秒，而INT/MODMayukh Bhattacharya 的解决方案（使用 的那个很不错c, SEQUENCE(a*b),）花费了 14 秒。您的MAKEARRAY解决方案花费了 23 秒。

如果/序列

• 为了更加熟悉此组合，请随意从我的下载重复列OneDrive。