主页 / coding / 问题 / 79194491
Accepted
We5inelgr
Asked: 2024-11-16 12:01:06 +0800 CST

如何在查询中使用带有 LIKE 的日期？

  • 772

我有一个 Google 表单（可提供给 Google 表格）供用户输入信息。其中一个字段是日期选择器，其格式如下mm/dd/yyyy。

我有一本包含多张工作表的工作簿。一张工作表（标签）捕获用户从 Google 文档表单输入的内容。它被称为“表单回复 1”。（例如）

在另一个选项卡上，我尝试根据来自 G 列的月份提取数据。

例如，在第一个单元格中，我尝试了这样的公式（尝试从到选择所有十二月的答案12/1/2025）12/31/2025：

=query('Form Responses 1' !A2:N, "Select * Where G like '12')

=query('Form Responses 1' !A2:N, "Select * Where G >= '12/1/2025' and <= '12/31/2025')

有谁知道如何让 LIKE‘12%’在日期选择器字段答案上起作用（我知道它不是一个字符串）或者以其他方式不使用 LIKE 返回月份或 mm 位置为 12 的每个答案？

google-sheets

3 个回答

  1. 假设您的日期选择器单元格B2使用以下QUERY()公式 -

    =QUERY('Form Responses 1' !A2:N,"select * where G>= date '" &TEXT(B2,"yyyy-mm-dd")& "' and G<= date '" & TEXT(EOMONTH(B2,0),"yyyy-mm-dd")& "'")

    如果你想手动输入日期，请​​尝试-

    =QUERY('Form Responses 1' !A2:N,"select * where G>= date '" &TEXT(DATE(2025,12,1),"yyyy-mm-dd")& "' and G<= date '" & TEXT(DATE(2025,12,31),"yyyy-mm-dd")& "'")
    • 2

  2. （尝试选择 2025 年 12 月 1 日至 2025 年 12 月 31 日期间的所有 12 月份答案）

    =query('Form Responses 1' !A2:N, "Select * Where G like '12')

    要使用硬编码参数执行此操作，请使用year()和month()，如下所示：

    =query('Form Responses 1' !A2:N, "where year(G) = 2025 and month(G)+1 = 12", 0)

    要获取与单元格中的日期位于同一月份的行D1，请使用以下命令：

    =query( 
  'Form Responses 1' !A2:N, 
  "where year(G) = " & year(D1) & 
  "and month(G)+1 = " & month(D1), 
  0 
)

    参见query()、year()和month()。

    • 1
  3. Best Answer

    需要注意的是，查询yyyy-MM-dd在内部使用格式date，无论您在外部使用什么格式（只要它被 Google 表格识别为日期格式）。因此，like将像这样工作：

    任意一年的十二月：
    "Select * Where G like '%-12-%'
    2024年12月：
    "Select * Where G like '2024-12-%'
    2024年12月10日至19日：
    "Select * Where G like '2024-12-1_'

    如果 G 是日期时间（而不仅仅是日期），我们需要在末尾添加一个通配符

    "Select * Where G like '2024-12-1_%'
    2020 年至 2029 年，任意月份，20 日至 29 日：
    "Select * Where G like '202_-%-2_'

    如果 G 是日期时间（而不仅仅是日期），我们需要在末尾添加一个通配符

    "Select * Where G like '202_-%-2_%'
    任何地方带有数字 12 的日期（2012 年或 2025 年 12 月 12 日）：
    "Select * Where G like '%12%'

    请注意，查询中的标量函数month提供不同的控制。

    任意一年的 12 月（第 11 个月，因为月份从 0（而不是 1）开始）：
    "Select * Where month(G)=11
    • 1

相关问题