grep 字符串，如果没有关系，则返回具有最高值的行

我会选择一个awk解决方案：

• 无需分类
• 消除了子 shell 的开销
• 轻松添加所需逻辑

一个awk想法：

awk -F, -v asv="29ec61e470705074f483368a70ad18a7" '
$1 == asv { if ($NF >= max_val) {
               if ($NF > max_val) {
                  delete matches
                  cnt = 0
                  max_val = $NF
               }
               matches[++cnt] = $0
            }
          }
END       { if (cnt == 0)
               print "WARNING: No lines found."
            else 
            if (cnt==1)
               print matches[cnt]
            else
               printf "CHECK: There are %s lines tied for top [max value = %s].\n", cnt, max_val
          }
' file.txt

为此asv="123"产生：

WARNING: No lines found.

为此asv="29ec61e470705074f483368a70ad18a7"产生：

29ec61e470705074f483368a70ad18a7,Bacteria,???,???,???,???,???,uncultured bacterium,5

为此asv="9966f0e6e452c31de46d030bab01fdd9"产生：

CHECK: There are 3 lines tied for top [max value = 2].

将其包装在bash函数中：

max_asv() {
awk -F, -v asv="$1" '
$1 == asv { if ($NF >= max_val) {
               if ($NF > max_val) {
                  delete matches
                  cnt = 0
                  max_val = $NF
               }
               matches[++cnt] = $0
            }
          }
END       { if (cnt == 0)
               print "WARNING: No lines found."
            else 
            if (cnt==1)
               print matches[cnt]
            else
               printf "CHECK: There are %s lines tied for top [max value = %s].\n", cnt, max_val
          }
' "$2"
}

对该功能进行测试：

$ max_asv 123 file.txt
WARNING: No lines found.

$ max_asv 29ec61e470705074f483368a70ad18a7 file.txt
29ec61e470705074f483368a70ad18a7,Bacteria,???,???,???,???,???,uncultured bacterium,5

$ max_asv 9966f0e6e452c31de46d030bab01fdd9 file.txt
CHECK: There are 3 lines tied for top [max value = 2].

用于awk仅匹配第一个字段中含有关键字的行。然后测试最后一个字段中的值是否等于或高于上次找到的最大值。如果相等，则增加计数器，否则将计数器重置为 1。

awk -F, -v key=29ec61e470705074f483368a70ad18a7 -v maxval=0 -v count=0 '
    $1 == key { line=$0;
                if ($9 > maxval) { maxval = $9; count = 1; } 
                else if ($9 == maxval) { count++; } }
    END { if (count == 1) { print line }
          else if (count > 1) { printf("CHECK: There are %d lines tied for top.\n", count) }
          else { print "CHECK: Line not found." } '

grep不适合这份工作。您可以使用以下awk解决方案：

cat srch.awk

BEGIN {FS=","}
FNR == NR {
   if ($1 == s && (!($1 in mx) || mx[$1] < $NF))
      mx[$1] = $NF
   next
}
$1 == s && $NF == mx[$1]

然后将其用作：

awk -v s='29ec61e470705074f483368a70ad18a7' -f srch.awk file file
29ec61e470705074f483368a70ad18a7,Bacteria,???,???,???,???,???,uncultured bacterium,5

awk -v s='9966f0e6e452c31de46d030bab01fdd9' -f srch.awk file file
9966f0e6e452c31de46d030bab01fdd9,Bacteria,Bacteroidota,Sphingobacteriia,Sphingobacteriales,???,???,uncultured Cytophagales,2
9966f0e6e452c31de46d030bab01fdd9,Bacteria,Bacteroidota,Cytophagia,Cytophagales,Cytophagaceae,Spirosoma,Spirosoma jeollabukense,2
9966f0e6e452c31de46d030bab01fdd9,Bacteria,Bacteroidota,Cytophagia,Cytophagales,Cytophagaceae,Spirosoma,Spirosoma migulaei,2

这是一个 Ruby 实现的：

$ cat parser.rb
require "csv"
puts "Usage: regexp file" if ARGV.length!=2
tbl=CSV.read(ARGV[1])
header=tbl.shift
asv=header.index("ASV")
hits=header.index("Hits")

regex=Regexp.new(ARGV[0])

if ((matches=tbl.select{|row| row[asv]=~regex}).length)==0 then  
    puts "No matches"
else
    top_n=matches.max_by{|row| row[hits].to_i }[hits]
    match_top=matches.select{|row| row[hits]==top_n}
    
    len=match_top.length
    err="CHECK: There are #{len} lines tied for top."
    
    puts len>1 ? err : match_top[0].to_csv 
end

运行它：

$ ruby parser.rb "^2" file.csv
29ec61e470705074f483368a70ad18a7,Bacteria,???,???,???,???,???,uncultured bacterium,5

$ ruby parser.rb "^9" file.csv
CHECK: There are 3 lines tied for top.

$ ruby parser.rb "^nothing" file.csv
No matches