主页 / coding / 问题 / 79168360
Accepted
bob freeman
Asked: 2024-11-08 07:16:11 +0800 CST

使用 gsub 进行模式匹配

  • 772

我尝试搜索并替换字符串的多个模式，并将其替换为不同的值。但是该命令仅替换一个模式，而忽略其余模式。

output=$(echo "$output4" | awk 'NR>1 {gsub(/\[|]/,""); gsub("+r","READ"); gsub("+r+w","READ and WRITE"); gsub("+r+w+g","READ, WRITE and GRANT"); print}')

当我执行脚本时，这就是我得到的结果。

    Group Analyst_Corp in security domain Native: READ. Group Finance_Dev in security domain Native: READ+w. Manufacturing_Corp in security domain Native: READ+w
Information_Tech in security domain Native: READ+w+g.

我正在寻找像这样的输出。

        Group Analyst_Corp in security domain Native: READ. Group Finance_Dev in security domain Native: READ and WRITE. Manufacturing_Corp in security domain Native: READ and WRITE
    Information_Tech in security domain Native: READ, WRITE and GRANT.
shell

3 个回答

  1. Best Answer

    猜测 OP 的输入（即output4变量的内容），并加入一些[字符]以便更好地衡量：

    output4="Some line to ignore
    Group [Analyst_Corp] in security domain [Native]: +r. Group [Finance_Dev] in security domain [Native]: +r+w. [Manufacturing_Corp] in security domain [Native]: +r+w
[Information_Tech] in security domain [Native]: +r+w+g."

    当前代码存在一些问题：

    • 当模式内容重叠时，您需要先替换较长的字符串（例如+r+w+g），然后再替换较短的字符串（例如+r）
    • 在正则表达式中具有+特殊含义，因此为了匹配文字，+我们需要对其进行转义（\+或[+]）
    • 如果你使用静态正则表达式（模式包含在一对字符中），那么在使用时\你会遇到更少的问题/
    • 转义时，[]可以使用动态（用双引号括起来的模式）或静态正则表达式
    • 虽然当前代码可以删除括号（[，]），但我们将换成一个更容易阅读/理解的不同正则表达式

    修改 OP 当前代码的几个不同选项：

    ########
# static regex; using `\` to escape the '+'

awk 'NR>1 { gsub(/[][]/,"")                             # remove brackets '[' and ']'
            gsub(/\+r\+w\+g/,"READ, WRITE and GRANT")
            gsub(/\+r\+w/,"READ and WRITE")
            gsub(/\+r/,"READ")
            print
          }
' <<< "${output4}"

########
# dynamic regex; using '[]' to escape the '+'

awk 'NR>1 { gsub(/[][]/,"")
            gsub("[+]r[+]w[+]g","READ, WRITE and GRANT")
            gsub("[+]r[+]w","READ and WRITE")
            gsub("[+]r","READ")
            print
          }
' <<< "${output4}"

########
# static regex; using '[]' to escape the '+'

awk 'NR>1 { gsub(/[][]/,"")
            gsub(/[+]r[+]w[+]g/,"READ, WRITE and GRANT")
            gsub(/[+]r[+]w/,"READ and WRITE")
            gsub(/[+]r/,"READ")
            print
          }
' <<< "${output4}"

    所有这些都会产生：

        Group Analyst_Corp in security domain Native: READ. Group Finance_Dev in security domain Native: READ and WRITE. Manufacturing_Corp in security domain Native: READ and WRITE
Information_Tech in security domain Native: READ, WRITE and GRANT.

    折叠为单行并将结果存储在变量中output：

    output=$(awk 'NR>1 {gsub(/[][]/,""); gsub(/\+r\+w\+g/,"READ, WRITE and GRANT"); gsub(/\+r\+w/,"READ and WRITE"); gsub(/\+r/,"READ"); print} ' <<< "${output4}")

output=$(awk 'NR>1 {gsub(/[][]/,""); gsub("[+]r[+]w[+]g","READ, WRITE and GRANT"); gsub("[+]r[+]w","READ and WRITE"); gsub("[+]r","READ"); print} ' <<< "${output4}")

output=$(awk 'NR>1 {gsub(/[][]/,""); gsub(/[+]r[+]w[+]g/,"READ, WRITE and GRANT"); gsub(/[+]r[+]w/,"READ and WRITE"); gsub(/[+]r/,"READ"); print} ' <<< "${output4}")

    所有这些都会产生：

    $ typeset -p output
declare -- output="        Group Analyst_Corp in security domain Native: READ. Group Finance_Dev in security domain Native: READ and WRITE. Manufacturing_Corp in security domain Native: READ and WRITE
    Information_Tech in security domain Native: READ, WRITE and GRANT."
    • 3

  2. +r+w按长度降序替换重叠的模式。否则替换后就找不到了+r。

    awk 'NR>1 {
    gsub(/\[|]/,""); 
    gsub(/\+r\+w\+g\/,"READ, WRITE and GRANT"); 
    gsub(/\+r\+w/,"READ and WRITE"); 
    gsub(/\+r/,"READ"); 
    print}'

    您还需要转义+，因为它在正则表达式中具有特殊含义。

    • 1

  3. 如果你对稍有不同（但含义相同）的输出不满意，你可以替换

    gsub("+r","READ"); gsub("+r+w","READ and WRITE"); gsub("+r+w+g","READ, WRITE and GRANT")

    使用

    gsub("[+]r","READ"); gsub("[+]w"," and WRITE"); gsub("[+]g"," and GRANT")

    让file.txt内容成为

    this +r is limited to read, whilst +r+w can also write, whilst +r+w+g has also right to grant

    然后

    awk '{gsub("[+]r","READ"); gsub("[+]w"," and WRITE"); gsub("[+]g"," and GRANT"); print}' file.txt

    给出输出

    this READ is limited to read, whilst READ and WRITE can also write, whilst READ and WRITE and GRANT has also right to grant

    请注意，而不是READ and WRITE and GRANT并且READ, WRITE and GRANT也将适用于独立+w和+g。

    （在 GNU Awk 5.1.0 中测试）

    • 1

相关问题