主页 / coding / 问题 / 79108288
Accepted
Pink Ninja
Asked: 2024-10-21 08:31:43 +0800 CST

如何在配置文件中交换配置实体？

  • 772

如果这个问题之前有人问过，我很抱歉，这个问题确实困扰了我几个小时，看起来相对简单。我在单个文件中通过 awk 识别了两个模式。

awk '/\[code\.change\..*\]/ {found=1; print; next} found && NF {print} found && !NF {exit}' filename
awk '/\[code\.test\..*\]/ {found=1; print; next} found && NF {print} found && !NF {exit}' filename

我可以将这两个 awk 合二为一来交换块吗？

配置文件的示例如下： file.cfg

[code.change.1]
file.path=filename
file.contact=manager
file.active=TRUE

[code.test.1]
ls -la filepath
pwd
find . -name filename

只需交换配置的顺序即可。谢谢

shell

3 个回答

  1. Best Answer

    根据提供的示例，请您尝试：

    awk -v RS= '                                                            # records are reparated by blank lines
    /^\[code\.change/ {pos1 = NR}                                       # position of the 1st block
    /^\[code\.test/ {pos2 = NR}                                         # position of the 2nd block
    {
        ary[NR] = $0                                                    # store the record in an array
    }
    END {
        tmp = ary[pos1]; ary[pos1] = ary[pos2]; ary[pos2] = tmp         # swap the two records
        for (i = 1; i <= NR; i++) print(ary[i], i<NR ? ORS : "")        # print the array
    }
' file.cfg
    • 5

  2. 如果ed可用/可接受，则类似于：

    #!/bin/sh

ed -s file.cfg <<'EOF'
  /^$/m$                                                ##: Move the blank/empty line at the end
  /^\[code\.change\.1\]/;/^\[code\.test\.1\]/-1m$       ##: From [code.change.1] down to [code.test.1] minus 1 line move to the end
  ,p                                                    ##: Print the changes from the buffer only, Does not edit the file.
  Q                                                     ##: Exit/quit silently
EOF

    一行

    printf '%s\n' '/^$/m$' '/^\[code\.change\.1\]/;/^\[code\.test\.1\]/-1m$' ,p Q | ed -s file.cfg

    如果你对输出/结果感到满意

    • 如果需要就地Q编辑，则更改为。w

    • 删除,p以使输出静音。

    • 参见 POSIX ed

    • 参见 GNU ed

    • 2

  3. 假设输入是一个只有 2 个块的文件，如问题中的示例所示，然后使用任何 awk：

    $ awk -v RS= -v OFS='\n\n' '{v[NR]=$0} END{print v[2], v[1]}' file.cfg
[code.test.1]
ls -la filepath
pwd
find . -name filename

[code.change.1]
file.path=filename
file.contact=manager
file.active=TRUE

    或者：

    $ awk -v RS= -v OFS='\n\n' 'NR==1{s=$0; next} {print $0, s}' file.cfg
[code.test.1]
ls -la filepath
pwd
find . -name filename

[code.change.1]
file.path=filename
file.contact=manager
file.active=TRUE

    或者使用 GNU awk 进行多字符 RS：

    $ awk -v RS='^$' -F'\n\n' -v OFS='\n' '{print $2, $1}' file.cfg
[code.test.1]
ls -la filepath
pwd
find . -name filename

[code.change.1]
file.path=filename
file.contact=manager
file.active=TRUE
    • 1

相关问题